source: josm/trunk/scripts/TagInfoExtract.groovy@ 10876

Last change on this file since 10876 was 10876, checked in by Don-vip, 8 years ago

fix #13309 - fix unit tests (patch by michael2402) - gsoc-core
  • Property svn:eol-style set to native
File size: 17.6 KB
RevLine 
[7544]1// License: GPL. For details, see LICENSE file.
2/**
3 * Extracts tag information for the taginfo project.
4 *
5 * Run from the base directory of a JOSM checkout:
6 *
[8306]7 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t mappaint
8 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t presets
[8681]9 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t external_presets
[7544]10 */
[8439]11import groovy.json.JsonBuilder
[8687]12
13import java.awt.image.BufferedImage
14import java.nio.file.FileSystems
15import java.nio.file.Files
16import java.nio.file.Path
17
18import javax.imageio.ImageIO
19
[7544]20import org.openstreetmap.josm.Main
[7625]21import org.openstreetmap.josm.data.Version
[7544]22import org.openstreetmap.josm.data.coor.LatLon
23import org.openstreetmap.josm.data.osm.Node
[9289]24import org.openstreetmap.josm.data.osm.OsmPrimitive
[7553]25import org.openstreetmap.josm.data.osm.Way
[7625]26import org.openstreetmap.josm.data.osm.visitor.paint.MapPaintSettings
27import org.openstreetmap.josm.data.osm.visitor.paint.StyledMapRenderer
[7544]28import org.openstreetmap.josm.data.projection.Projections
[7625]29import org.openstreetmap.josm.gui.NavigatableComponent
[7544]30import org.openstreetmap.josm.gui.mappaint.Environment
[8687]31import org.openstreetmap.josm.gui.mappaint.MultiCascade
[8681]32import org.openstreetmap.josm.gui.mappaint.MapPaintStyles.IconReference
[8687]33import org.openstreetmap.josm.gui.mappaint.mapcss.MapCSSStyleSource
[10837]34import org.openstreetmap.josm.gui.mappaint.mapcss.ConditionFactory.SimpleKeyValueCondition
[7625]35import org.openstreetmap.josm.gui.mappaint.mapcss.Selector.GeneralSelector
[7544]36import org.openstreetmap.josm.gui.mappaint.mapcss.parsergen.MapCSSParser
[9289]37import org.openstreetmap.josm.gui.mappaint.styleelement.AreaElement
[9283]38import org.openstreetmap.josm.gui.mappaint.styleelement.LineElement
[9289]39import org.openstreetmap.josm.gui.mappaint.styleelement.StyleElement
[8681]40import org.openstreetmap.josm.gui.preferences.map.TaggingPresetPreference
[8863]41import org.openstreetmap.josm.gui.tagging.presets.TaggingPreset
42import org.openstreetmap.josm.gui.tagging.presets.TaggingPresetReader
43import org.openstreetmap.josm.gui.tagging.presets.TaggingPresetType
44import org.openstreetmap.josm.gui.tagging.presets.items.KeyedItem
45import org.openstreetmap.josm.gui.tagging.presets.items.KeyedItem.MatchType
[7544]46import org.openstreetmap.josm.io.CachedFile
[8274]47import org.openstreetmap.josm.tools.Utils
[7544]48
[9880]49class TagInfoExtract {
[7544]50
[7553]51 static def options
52 static String image_dir
53 int josm_svn_revision
54 String input_file
55 MapCSSStyleSource style_source
56 FileWriter output_file
[9289]57 String base_dir = "."
58 Set tags = []
[7625]59
[7553]60 private def cached_svnrev
[7544]61
[7553]62 /**
63 * Check if a certain tag is supported by the style as node / way / area.
64 */
65 abstract class Checker {
[7625]66
[7553]67 def tag
[9289]68 OsmPrimitive osm
[7625]69
[7553]70 Checker(tag) {
71 this.tag = tag
72 }
[7625]73
[9289]74 Environment apply_stylesheet(OsmPrimitive osm) {
[7553]75 osm.put(tag[0], tag[1])
[9289]76 MultiCascade mc = new MultiCascade()
[7625]77
[9289]78 Environment env = new Environment(osm, mc, null, style_source)
[7553]79 for (def r in style_source.rules) {
80 env.clearSelectorMatchingInformation()
81 if (r.selector.matches(env)) {
82 // ignore selector range
83 if (env.layer == null) {
84 env.layer = "default"
85 }
86 r.execute(env)
87 }
88 }
89 env.layer = "default"
90 return env
91 }
[7625]92
[7553]93 /**
[9289]94 * Create image file from StyleElement.
[7553]95 * @return the URL
[7625]96 */
[9289]97 def create_image(StyleElement elem_style, type, nc) {
[7553]98 def img = new BufferedImage(16, 16, BufferedImage.TYPE_INT_ARGB)
99 def g = img.createGraphics()
100 g.setClip(0, 0, 16, 16)
101 def renderer = new StyledMapRenderer(g, nc, false)
102 renderer.getSettings(false)
[7625]103 elem_style.paintPrimitive(osm, MapPaintSettings.INSTANCE, renderer, false, false, false)
[7554]104 def base_url = options.imgurlprefix ? options.imgurlprefix : image_dir
105 def image_name = "${type}_${tag[0]}=${tag[1]}.png"
106 ImageIO.write(img, "png", new File("${image_dir}/${image_name}"))
107 return "${base_url}/${image_name}"
[7553]108 }
[7544]109
[7553]110 /**
111 * Checks, if tag is supported and find URL for image icon in this case.
112 * @param generate_image if true, create or find a suitable image icon and return URL,
113 * if false, just check if tag is supported and return true or false
114 */
115 abstract def find_url(boolean generate_image)
116 }
[7544]117
[7553]118 class NodeChecker extends Checker {
119 NodeChecker(tag) {
120 super(tag)
121 }
122
[9953]123 @Override
[7553]124 def find_url(boolean generate_image) {
[9214]125 osm = new Node(LatLon.ZERO)
[7553]126 def env = apply_stylesheet(osm)
127 def c = env.mc.getCascade("default")
128 def image = c.get("icon-image")
129 if (image) {
130 if (image instanceof IconReference) {
[10872]131 if (image.iconName != "misc/deprecated.svg")
[7553]132 return find_image_url(image.iconName)
133 }
134 }
135 }
[7544]136 }
137
[7553]138 class WayChecker extends Checker {
139 WayChecker(tag) {
140 super(tag)
141 }
142
[9953]143 @Override
[7553]144 def find_url(boolean generate_image) {
145 osm = new Way()
146 def nc = new NavigatableComponent()
147 def n1 = new Node(nc.getLatLon(2,8))
148 def n2 = new Node(nc.getLatLon(14,8))
[9289]149 ((Way)osm).addNode(n1)
150 ((Way)osm).addNode(n2)
[7553]151 def env = apply_stylesheet(osm)
[9283]152 def les = LineElement.createLine(env)
[7553]153 if (les != null) {
154 if (!generate_image) return true
155 return create_image(les, 'way', nc)
156 }
157 }
[7544]158 }
[7553]159
160 class AreaChecker extends Checker {
161 AreaChecker(tag) {
162 super(tag)
163 }
164
[9953]165 @Override
[7553]166 def find_url(boolean generate_image) {
167 osm = new Way()
168 def nc = new NavigatableComponent()
169 def n1 = new Node(nc.getLatLon(2,2))
170 def n2 = new Node(nc.getLatLon(14,2))
171 def n3 = new Node(nc.getLatLon(14,14))
172 def n4 = new Node(nc.getLatLon(2,14))
[9289]173 ((Way)osm).addNode(n1)
174 ((Way)osm).addNode(n2)
175 ((Way)osm).addNode(n3)
176 ((Way)osm).addNode(n4)
177 ((Way)osm).addNode(n1)
[7553]178 def env = apply_stylesheet(osm)
[9289]179 def aes = AreaElement.create(env)
[7553]180 if (aes != null) {
181 if (!generate_image) return true
182 return create_image(aes, 'area', nc)
183 }
184 }
[7544]185 }
186
[7553]187 /**
188 * Main method.
189 */
190 static main(def args) {
191 parse_command_line_arguments(args)
[9880]192 def script = new TagInfoExtract()
[8274]193 if (!options.t || options.t == 'mappaint') {
194 script.run()
195 } else if (options.t == 'presets') {
196 script.run_presets()
[8681]197 } else if (options.t == 'external_presets') {
198 script.run_external_presets()
[8274]199 } else {
200 System.err.println 'Invalid type ' + options.t
[8687]201 if (!options.noexit) {
202 System.exit(1)
203 }
[8274]204 }
205
[8687]206 if (!options.noexit) {
207 System.exit(0)
208 }
[7553]209 }
[7544]210
[7553]211 /**
212 * Parse command line arguments.
213 */
214 static void parse_command_line_arguments(args) {
215 def cli = new CliBuilder(usage:'taginfoextract.groovy [options] [inputfile]',
216 header:"Options:",
[7936]217 footer:"[inputfile] the file to process (optional, default is 'resource://styles/standard/elemstyles.mapcss')")
218 cli.o(args:1, argName: "file", "output file (json), - prints to stdout (default: -)")
[8274]219 cli.t(args:1, argName: "type", "the project type to be generated")
220 cli._(longOpt:'svnrev', args:1, argName:"revision", "corresponding revision of the repository https://svn.openstreetmap.org/ (optional, current revision is read from the local checkout or from the web if not given, see --svnweb)")
[7553]221 cli._(longOpt:'imgdir', args:1, argName:"directory", "directory to put the generated images in (default: ./taginfo-img)")
[8687]222 cli._(longOpt:'noexit', "don't call System.exit(), for use from Ant script")
[8274]223 cli._(longOpt:'svnweb', 'fetch revision of the repository https://svn.openstreetmap.org/ from web and not from the local repository')
[7554]224 cli._(longOpt:'imgurlprefix', args:1, argName:'prefix', 'image URLs prefix for generated image files')
[7553]225 cli.h(longOpt:'help', "show this help")
226 options = cli.parse(args)
[7544]227
[7553]228 if (options.h) {
229 cli.usage()
230 System.exit(0)
231 }
232 if (options.arguments().size() > 1) {
233 System.err.println "Error: More than one input file given!"
234 cli.usage()
235 System.exit(-1)
236 }
237 if (options.svnrev) {
238 assert Integer.parseInt(options.svnrev) > 0
239 }
240 image_dir = 'taginfo-img'
241 if (options.imgdir) {
242 image_dir = options.imgdir
243 }
244 def image_dir_file = new File(image_dir)
245 if (!image_dir_file.exists()) {
246 image_dir_file.mkdirs()
247 }
248 }
[7625]249
[8274]250 void run_presets() {
251 init()
[8681]252 def presets = TaggingPresetReader.readAll(input_file, true)
[8690]253 def tags = convert_presets(presets, "", true)
[8681]254 write_json("JOSM main presets", "Tags supported by the default presets in the OSM editor JOSM", tags)
255 }
256
257 def convert_presets(Iterable<TaggingPreset> presets, String descriptionPrefix, boolean addImages) {
[8274]258 def tags = []
259 for (TaggingPreset preset : presets) {
[8863]260 for (KeyedItem item : Utils.filteredCollection(preset.data, KeyedItem.class)) {
[8274]261 def values
[8863]262 switch (MatchType.ofString(item.match)) {
263 case MatchType.KEY_REQUIRED: values = item.getValues(); break;
264 case MatchType.KEY_VALUE_REQUIRED: values = item.getValues(); break;
[8274]265 default: values = [];
266 }
267 for (String value : values) {
268 def tag = [
[8681]269 description: descriptionPrefix + preset.name,
[8274]270 key: item.key,
271 value: value,
272 ]
[10769]273 def otypes = preset.types.collect {
274 it == TaggingPresetType.CLOSEDWAY ? "area" :
275 (it == TaggingPresetType.MULTIPOLYGON ? "relation" : it.toString().toLowerCase(Locale.ENGLISH))
276 }
277 if (!otypes.isEmpty()) tag += [object_types: otypes]
[8681]278 if (addImages && preset.iconName) tag += [icon_url: find_image_url(preset.iconName)]
[8274]279 tags += tag
280 }
281 }
282 }
[8681]283 return tags
284 }
[8274]285
[8681]286 void run_external_presets() {
287 init()
[8710]288 TaggingPresetReader.setLoadIcons(false)
[8681]289 def sources = new TaggingPresetPreference.TaggingPresetSourceEditor().loadAndGetAvailableSources()
290 def tags = []
291 for (def source : sources) {
292 if (source.url.startsWith("resource")) {
293 // default presets
294 continue;
295 }
296 try {
297 println "Loading ${source.url}"
298 def presets = TaggingPresetReader.readAll(source.url, false)
299 def t = convert_presets(presets, source.title + " ", false)
300 println "Converting ${t.size()} presets of ${source.title}"
301 tags += t
302 } catch (Exception ex) {
303 System.err.println("Skipping ${source.url} due to error")
304 ex.printStackTrace()
305 }
306 }
307 write_json("JOSM user presets", "Tags supported by the user contributed presets in the OSM editor JOSM", tags)
[8274]308 }
309
[7553]310 void run() {
311 init()
312 parse_style_sheet()
313 collect_tags()
[7544]314
[8272]315 def tags = tags.collect {
316 def tag = it
[7553]317 def types = []
318 def final_url = null
319
320 def node_url = new NodeChecker(tag).find_url(true)
321 if (node_url) {
[8272]322 types += 'node'
[7553]323 final_url = node_url
324 }
325 def way_url = new WayChecker(tag).find_url(final_url == null)
326 if (way_url) {
[8272]327 types += 'way'
[7553]328 if (!final_url) {
329 final_url = way_url
[7544]330 }
331 }
[7553]332 def area_url = new AreaChecker(tag).find_url(final_url == null)
333 if (area_url) {
[8272]334 types += 'area'
[7553]335 if (!final_url) {
336 final_url = area_url
337 }
338 }
[7625]339
[8272]340 def obj = [key: tag[0], value: tag[1]]
341 if (types) obj += [object_types: types]
342 if (final_url) obj += [icon_url: final_url]
343 obj
[7625]344 }
[7553]345
[8274]346 write_json("JOSM main mappaint style", "Tags supported by the main mappaint style in the OSM editor JOSM", tags)
[7544]347 }
348
[8274]349 void write_json(name, description, tags) {
[8272]350 def json = new JsonBuilder()
351 def project = [
352 name: name,
353 description: description,
[8274]354 project_url: "https://josm.openstreetmap.de/",
355 icon_url: "https://josm.openstreetmap.de/export/7770/josm/trunk/images/logo_16x16x8.png",
[8272]356 contact_name: "JOSM developer team",
357 contact_email: "josm-dev@openstreetmap.org",
358 ]
[10769]359 json data_format: 1, data_updated: new Date().format("yyyyMMdd'T'hhmmss'Z'", TimeZone.getTimeZone('UTC')), project: project, tags: tags
[8274]360
361 if (output_file != null) {
362 json.writeTo(output_file)
363 output_file.close()
364 } else {
365 print json.toPrettyString()
366 }
[8272]367 }
368
[7553]369 /**
370 * Initialize the script.
371 */
372 def init() {
[8681]373 Main.determinePlatformHook()
[7553]374 Main.pref.enableSaveOnPut(false)
375 Main.setProjection(Projections.getProjectionByCode("EPSG:3857"))
[8275]376 Path tmpdir = Files.createTempDirectory(FileSystems.getDefault().getPath(base_dir), "pref")
[8717]377 tmpdir.toFile().deleteOnExit()
[8275]378 System.setProperty("josm.home", tmpdir.toString())
[7544]379
[7553]380 josm_svn_revision = Version.getInstance().getVersion()
381 assert josm_svn_revision != Version.JOSM_UNKNOWN_VERSION
[7544]382
[8274]383 if (options.arguments().size() == 0 && (!options.t || options.t == 'mappaint')) {
[7553]384 input_file = "resource://styles/standard/elemstyles.mapcss"
[8274]385 } else if (options.arguments().size() == 0 && options.t == 'presets') {
386 input_file = "resource://data/defaultpresets.xml"
[7553]387 } else {
388 input_file = options.arguments()[0]
389 }
[7544]390
[7553]391 output_file = null
392 if (options.o && options.o != "-") {
393 output_file = new FileWriter(options.o)
394 }
395 }
[7544]396
[7553]397 /**
[8274]398 * Determine full image url (can refer to JOSM or OSM repository).
[7553]399 */
[9289]400 def find_image_url(String path) {
[8274]401 def f = new File("${base_dir}/images/styles/standard/${path}")
402 if (f.exists()) {
403 def rev = osm_svn_revision()
404 return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
405 }
406 f = new File("${base_dir}/images/${path}")
407 if (f.exists()) {
[8439]408 if (path.startsWith("images/styles/standard/")) {
409 path = path.substring("images/styles/standard/".length())
410 def rev = osm_svn_revision()
411 return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
[8671]412 } else if (path.startsWith("styles/standard/")) {
413 path = path.substring("styles/standard/".length())
414 def rev = osm_svn_revision()
415 return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
[8439]416 } else {
417 return "https://josm.openstreetmap.de/export/${josm_svn_revision}/josm/trunk/images/${path}"
418 }
[8274]419 }
420 assert false, "Cannot find image url for ${path}"
421 }
422
423 /**
424 * Get revision for the repository https://svn.openstreetmap.org.
425 */
[7553]426 def osm_svn_revision() {
427 if (cached_svnrev != null) return cached_svnrev
428 if (options.svnrev) {
429 cached_svnrev = Integer.parseInt(options.svnrev)
430 return cached_svnrev
431 }
432 def xml
433 if (options.svnweb) {
[8274]434 xml = "svn info --xml https://svn.openstreetmap.org/applications/share/map-icons/classic.small".execute().text
[7553]435 } else {
436 xml = "svn info --xml ${base_dir}/images/styles/standard/".execute().text
437 }
[7625]438
[7553]439 def svninfo = new XmlParser().parseText(xml)
440 def rev = svninfo.entry.'@revision'[0]
441 cached_svnrev = Integer.parseInt(rev)
442 assert cached_svnrev > 0
443 return cached_svnrev
444 }
[7625]445
[7553]446 /**
447 * Read the style sheet file and parse the MapCSS code.
448 */
449 def parse_style_sheet() {
450 def file = new CachedFile(input_file)
451 def stream = file.getInputStream()
452 def parser = new MapCSSParser(stream, "UTF-8", MapCSSParser.LexicalState.DEFAULT)
453 style_source = new MapCSSStyleSource("")
454 style_source.url = ""
455 parser.sheet(style_source)
456 }
[7625]457
[7553]458 /**
459 * Collect all the tag from the style sheet.
460 */
461 def collect_tags() {
462 for (rule in style_source.rules) {
463 def selector = rule.selector
464 if (selector instanceof GeneralSelector) {
465 def conditions = selector.getConditions()
466 for (cond in conditions) {
467 if (cond instanceof SimpleKeyValueCondition) {
468 tags.add([cond.k, cond.v])
469 }
470 }
[7544]471 }
472 }
473 }
474}
Note: See TracBrowser for help on using the repository browser.