source: josm/trunk/scripts/TagInfoExtract.groovy @ 10927

Last change on this file since 10927 was 10927, checked in by simon04, 7 years ago

see #13217 - Only one location for deprecated icon names
  • Property svn:eol-style set to native
File size: 17.6 KB
Line 
1// License: GPL. For details, see LICENSE file.
2/**
3 * Extracts tag information for the taginfo project.
4 *
5 * Run from the base directory of a JOSM checkout:
6 *
7 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t mappaint
8 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t presets
9 * groovy -cp dist/josm-custom.jar scripts/taginfoextract.groovy -t external_presets
10 */
11import groovy.json.JsonBuilder
12
13import java.awt.image.BufferedImage
14import java.nio.file.FileSystems
15import java.nio.file.Files
16import java.nio.file.Path
17
18import javax.imageio.ImageIO
19
20import org.openstreetmap.josm.Main
21import org.openstreetmap.josm.data.Version
22import org.openstreetmap.josm.data.coor.LatLon
23import org.openstreetmap.josm.data.osm.Node
24import org.openstreetmap.josm.data.osm.OsmPrimitive
25import org.openstreetmap.josm.data.osm.Way
26import org.openstreetmap.josm.data.osm.visitor.paint.MapPaintSettings
27import org.openstreetmap.josm.data.osm.visitor.paint.StyledMapRenderer
28import org.openstreetmap.josm.data.projection.Projections
29import org.openstreetmap.josm.gui.NavigatableComponent
30import org.openstreetmap.josm.gui.mappaint.Environment
31import org.openstreetmap.josm.gui.mappaint.MultiCascade
32import org.openstreetmap.josm.gui.mappaint.MapPaintStyles.IconReference
33import org.openstreetmap.josm.gui.mappaint.mapcss.MapCSSStyleSource
34import org.openstreetmap.josm.gui.mappaint.mapcss.ConditionFactory.SimpleKeyValueCondition
35import org.openstreetmap.josm.gui.mappaint.mapcss.Selector.GeneralSelector
36import org.openstreetmap.josm.gui.mappaint.mapcss.parsergen.MapCSSParser
37import org.openstreetmap.josm.gui.mappaint.styleelement.AreaElement
38import org.openstreetmap.josm.gui.mappaint.styleelement.LineElement
39import org.openstreetmap.josm.gui.mappaint.styleelement.StyleElement
40import org.openstreetmap.josm.gui.preferences.map.TaggingPresetPreference
41import org.openstreetmap.josm.gui.tagging.presets.TaggingPreset
42import org.openstreetmap.josm.gui.tagging.presets.TaggingPresetReader
43import org.openstreetmap.josm.gui.tagging.presets.TaggingPresetType
44import org.openstreetmap.josm.gui.tagging.presets.items.KeyedItem
45import org.openstreetmap.josm.gui.tagging.presets.items.KeyedItem.MatchType
46import org.openstreetmap.josm.io.CachedFile
47import org.openstreetmap.josm.tools.Utils
48
49class TagInfoExtract {
50
51    static def options
52    static String image_dir
53    int josm_svn_revision
54    String input_file
55    MapCSSStyleSource style_source
56    FileWriter output_file
57    String base_dir = "."
58    Set tags = []
59
60    private def cached_svnrev
61
62    /**
63     * Check if a certain tag is supported by the style as node / way / area.
64     */
65    abstract class Checker {
66
67        def tag
68        OsmPrimitive osm
69
70        Checker(tag) {
71            this.tag = tag
72        }
73
74        Environment apply_stylesheet(OsmPrimitive osm) {
75            osm.put(tag[0], tag[1])
76            MultiCascade mc = new MultiCascade()
77
78            Environment env = new Environment(osm, mc, null, style_source)
79            for (def r in style_source.rules) {
80                env.clearSelectorMatchingInformation()
81                if (r.selector.matches(env)) {
82                    // ignore selector range
83                    if (env.layer == null) {
84                        env.layer = "default"
85                    }
86                    r.execute(env)
87                }
88            }
89            env.layer = "default"
90            return env
91        }
92
93        /**
94         * Create image file from StyleElement.
95         * @return the URL
96         */
97        def create_image(StyleElement elem_style, type, nc) {
98            def img = new BufferedImage(16, 16, BufferedImage.TYPE_INT_ARGB)
99            def g = img.createGraphics()
100            g.setClip(0, 0, 16, 16)
101            def renderer = new StyledMapRenderer(g, nc, false)
102            renderer.getSettings(false)
103            elem_style.paintPrimitive(osm, MapPaintSettings.INSTANCE, renderer, false, false, false)
104            def base_url = options.imgurlprefix ? options.imgurlprefix : image_dir
105            def image_name = "${type}_${tag[0]}=${tag[1]}.png"
106            ImageIO.write(img, "png", new File("${image_dir}/${image_name}"))
107            return "${base_url}/${image_name}"
108        }
109
110        /**
111         * Checks, if tag is supported and find URL for image icon in this case.
112         * @param generate_image if true, create or find a suitable image icon and return URL,
113         * if false, just check if tag is supported and return true or false
114         */
115        abstract def find_url(boolean generate_image)
116    }
117
118    class NodeChecker extends Checker {
119        NodeChecker(tag) {
120            super(tag)
121        }
122
123        @Override
124        def find_url(boolean generate_image) {
125            osm = new Node(LatLon.ZERO)
126            def env = apply_stylesheet(osm)
127            def c = env.mc.getCascade("default")
128            def image = c.get("icon-image")
129            if (image) {
130                if (image instanceof IconReference && !image.isDeprecatedIcon()) {
131                    return find_image_url(image.iconName)
132                }
133            }
134        }
135    }
136
137    class WayChecker extends Checker {
138        WayChecker(tag) {
139            super(tag)
140        }
141
142        @Override
143        def find_url(boolean generate_image) {
144            osm = new Way()
145            def nc = new NavigatableComponent()
146            def n1 = new Node(nc.getLatLon(2,8))
147            def n2 = new Node(nc.getLatLon(14,8))
148            ((Way)osm).addNode(n1)
149            ((Way)osm).addNode(n2)
150            def env = apply_stylesheet(osm)
151            def les = LineElement.createLine(env)
152            if (les != null) {
153                if (!generate_image) return true
154                return create_image(les, 'way', nc)
155            }
156        }
157    }
158
159    class AreaChecker extends Checker {
160        AreaChecker(tag) {
161            super(tag)
162        }
163
164        @Override
165        def find_url(boolean generate_image) {
166            osm = new Way()
167            def nc = new NavigatableComponent()
168            def n1 = new Node(nc.getLatLon(2,2))
169            def n2 = new Node(nc.getLatLon(14,2))
170            def n3 = new Node(nc.getLatLon(14,14))
171            def n4 = new Node(nc.getLatLon(2,14))
172            ((Way)osm).addNode(n1)
173            ((Way)osm).addNode(n2)
174            ((Way)osm).addNode(n3)
175            ((Way)osm).addNode(n4)
176            ((Way)osm).addNode(n1)
177            def env = apply_stylesheet(osm)
178            def aes = AreaElement.create(env)
179            if (aes != null) {
180                if (!generate_image) return true
181                return create_image(aes, 'area', nc)
182            }
183        }
184    }
185
186    /**
187     * Main method.
188     */
189    static main(def args) {
190        parse_command_line_arguments(args)
191        def script = new TagInfoExtract()
192        if (!options.t || options.t == 'mappaint') {
193            script.run()
194        } else if (options.t == 'presets') {
195            script.run_presets()
196        } else if (options.t == 'external_presets') {
197            script.run_external_presets()
198        } else {
199            System.err.println 'Invalid type ' + options.t
200            if (!options.noexit) {
201                System.exit(1)
202            }
203        }
204
205        if (!options.noexit) {
206            System.exit(0)
207        }
208    }
209
210    /**
211     * Parse command line arguments.
212     */
213    static void parse_command_line_arguments(args) {
214        def cli = new CliBuilder(usage:'taginfoextract.groovy [options] [inputfile]',
215            header:"Options:",
216            footer:"[inputfile]           the file to process (optional, default is 'resource://styles/standard/elemstyles.mapcss')")
217        cli.o(args:1, argName: "file", "output file (json), - prints to stdout (default: -)")
218        cli.t(args:1, argName: "type", "the project type to be generated")
219        cli._(longOpt:'svnrev', args:1, argName:"revision", "corresponding revision of the repository https://svn.openstreetmap.org/ (optional, current revision is read from the local checkout or from the web if not given, see --svnweb)")
220        cli._(longOpt:'imgdir', args:1, argName:"directory", "directory to put the generated images in (default: ./taginfo-img)")
221        cli._(longOpt:'noexit', "don't call System.exit(), for use from Ant script")
222        cli._(longOpt:'svnweb', 'fetch revision of the repository https://svn.openstreetmap.org/ from web and not from the local repository')
223        cli._(longOpt:'imgurlprefix', args:1, argName:'prefix', 'image URLs prefix for generated image files')
224        cli.h(longOpt:'help', "show this help")
225        options = cli.parse(args)
226
227        if (options.h) {
228            cli.usage()
229            System.exit(0)
230        }
231        if (options.arguments().size() > 1) {
232            System.err.println "Error: More than one input file given!"
233            cli.usage()
234            System.exit(-1)
235        }
236        if (options.svnrev) {
237            assert Integer.parseInt(options.svnrev) > 0
238        }
239        image_dir = 'taginfo-img'
240        if (options.imgdir) {
241            image_dir = options.imgdir
242        }
243        def image_dir_file = new File(image_dir)
244        if (!image_dir_file.exists()) {
245            image_dir_file.mkdirs()
246        }
247    }
248
249    void run_presets() {
250        init()
251        def presets = TaggingPresetReader.readAll(input_file, true)
252        def tags = convert_presets(presets, "", true)
253        write_json("JOSM main presets", "Tags supported by the default presets in the OSM editor JOSM", tags)
254    }
255
256    def convert_presets(Iterable<TaggingPreset> presets, String descriptionPrefix, boolean addImages) {
257        def tags = []
258        for (TaggingPreset preset : presets) {
259            for (KeyedItem item : Utils.filteredCollection(preset.data, KeyedItem.class)) {
260                def values
261                switch (MatchType.ofString(item.match)) {
262                    case MatchType.KEY_REQUIRED: values = item.getValues(); break;
263                    case MatchType.KEY_VALUE_REQUIRED: values = item.getValues(); break;
264                    default: values = [];
265                }
266                for (String value : values) {
267                    def tag = [
268                            description: descriptionPrefix + preset.name,
269                            key: item.key,
270                            value: value,
271                    ]
272                    def otypes = preset.types.collect {
273                        it == TaggingPresetType.CLOSEDWAY ? "area" :
274                            (it == TaggingPresetType.MULTIPOLYGON ? "relation" : it.toString().toLowerCase(Locale.ENGLISH))
275                    }
276                    if (!otypes.isEmpty()) tag += [object_types: otypes]
277                    if (addImages && preset.iconName) tag += [icon_url: find_image_url(preset.iconName)]
278                    tags += tag
279                }
280            }
281        }
282        return tags
283    }
284
285    void run_external_presets() {
286        init()
287        TaggingPresetReader.setLoadIcons(false)
288        def sources = new TaggingPresetPreference.TaggingPresetSourceEditor().loadAndGetAvailableSources()
289        def tags = []
290        for (def source : sources) {
291            if (source.url.startsWith("resource")) {
292                // default presets
293                continue;
294            }
295            try {
296                println "Loading ${source.url}"
297                def presets = TaggingPresetReader.readAll(source.url, false)
298                def t = convert_presets(presets, source.title + " ", false)
299                println "Converting ${t.size()} presets of ${source.title}"
300                tags += t
301            } catch (Exception ex) {
302                System.err.println("Skipping ${source.url} due to error")
303                ex.printStackTrace()
304            }
305        }
306        write_json("JOSM user presets", "Tags supported by the user contributed presets in the OSM editor JOSM", tags)
307    }
308
309    void run() {
310        init()
311        parse_style_sheet()
312        collect_tags()
313
314        def tags = tags.collect {
315            def tag = it
316            def types = []
317            def final_url = null
318
319            def node_url = new NodeChecker(tag).find_url(true)
320            if (node_url) {
321                types += 'node'
322                final_url = node_url
323            }
324            def way_url = new WayChecker(tag).find_url(final_url == null)
325            if (way_url) {
326                types += 'way'
327                if (!final_url) {
328                    final_url = way_url
329                }
330            }
331            def area_url = new AreaChecker(tag).find_url(final_url == null)
332            if (area_url) {
333                types += 'area'
334                if (!final_url) {
335                    final_url = area_url
336                }
337            }
338
339            def obj = [key: tag[0], value: tag[1]]
340            if (types) obj += [object_types: types]
341            if (final_url) obj += [icon_url: final_url]
342            obj
343        }
344
345        write_json("JOSM main mappaint style", "Tags supported by the main mappaint style in the OSM editor JOSM", tags)
346    }
347
348    void write_json(name, description, tags) {
349        def json = new JsonBuilder()
350        def project = [
351                name: name,
352                description: description,
353                project_url: "https://josm.openstreetmap.de/",
354                icon_url: "https://josm.openstreetmap.de/export/7770/josm/trunk/images/logo_16x16x8.png",
355                contact_name: "JOSM developer team",
356                contact_email: "josm-dev@openstreetmap.org",
357        ]
358        json data_format: 1, data_updated: new Date().format("yyyyMMdd'T'hhmmss'Z'", TimeZone.getTimeZone('UTC')), project: project, tags: tags
359
360        if (output_file != null) {
361            json.writeTo(output_file)
362            output_file.close()
363        } else {
364            print json.toPrettyString()
365        }
366    }
367
368    /**
369     * Initialize the script.
370     */
371    def init() {
372        Main.determinePlatformHook()
373        Main.pref.enableSaveOnPut(false)
374        Main.setProjection(Projections.getProjectionByCode("EPSG:3857"))
375        Path tmpdir = Files.createTempDirectory(FileSystems.getDefault().getPath(base_dir), "pref")
376        tmpdir.toFile().deleteOnExit()
377        System.setProperty("josm.home", tmpdir.toString())
378
379        josm_svn_revision = Version.getInstance().getVersion()
380        assert josm_svn_revision != Version.JOSM_UNKNOWN_VERSION
381
382        if (options.arguments().size() == 0 && (!options.t || options.t == 'mappaint')) {
383            input_file = "resource://styles/standard/elemstyles.mapcss"
384        } else if (options.arguments().size() == 0 && options.t == 'presets') {
385            input_file = "resource://data/defaultpresets.xml"
386        } else {
387            input_file = options.arguments()[0]
388        }
389
390        output_file = null
391        if (options.o && options.o != "-") {
392            output_file = new FileWriter(options.o)
393        }
394    }
395
396    /**
397     * Determine full image url (can refer to JOSM or OSM repository).
398     */
399    def find_image_url(String path) {
400        def f = new File("${base_dir}/images/styles/standard/${path}")
401        if (f.exists()) {
402            def rev = osm_svn_revision()
403            return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
404        }
405        f = new File("${base_dir}/images/${path}")
406        if (f.exists()) {
407            if (path.startsWith("images/styles/standard/")) {
408                path = path.substring("images/styles/standard/".length())
409                def rev = osm_svn_revision()
410                return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
411            } else if (path.startsWith("styles/standard/")) {
412                path = path.substring("styles/standard/".length())
413                def rev = osm_svn_revision()
414                return "https://trac.openstreetmap.org/export/${rev}/subversion/applications/share/map-icons/classic.small/${path}"
415            } else {
416                return "https://josm.openstreetmap.de/export/${josm_svn_revision}/josm/trunk/images/${path}"
417            }
418        }
419        assert false, "Cannot find image url for ${path}"
420    }
421
422    /**
423     * Get revision for the repository https://svn.openstreetmap.org.
424     */
425    def osm_svn_revision() {
426        if (cached_svnrev != null) return cached_svnrev
427        if (options.svnrev) {
428            cached_svnrev = Integer.parseInt(options.svnrev)
429            return cached_svnrev
430        }
431        def xml
432        if (options.svnweb) {
433            xml = "svn info --xml https://svn.openstreetmap.org/applications/share/map-icons/classic.small".execute().text
434        } else {
435            xml = "svn info --xml ${base_dir}/images/styles/standard/".execute().text
436        }
437
438        def svninfo = new XmlParser().parseText(xml)
439        def rev = svninfo.entry.'@revision'[0]
440        cached_svnrev = Integer.parseInt(rev)
441        assert cached_svnrev > 0
442        return cached_svnrev
443    }
444
445    /**
446     * Read the style sheet file and parse the MapCSS code.
447     */
448    def parse_style_sheet() {
449        def file = new CachedFile(input_file)
450        def stream = file.getInputStream()
451        def parser = new MapCSSParser(stream, "UTF-8", MapCSSParser.LexicalState.DEFAULT)
452        style_source = new MapCSSStyleSource("")
453        style_source.url = ""
454        parser.sheet(style_source)
455    }
456
457    /**
458     * Collect all the tag from the style sheet.
459     */
460    def collect_tags() {
461        for (rule in style_source.rules) {
462            def selector = rule.selector
463            if (selector instanceof GeneralSelector) {
464                def conditions = selector.getConditions()
465                for (cond in conditions) {
466                    if (cond instanceof SimpleKeyValueCondition) {
467                        tags.add([cond.k, cond.v])
468                    }
469                }
470            }
471        }
472    }
473}
Note: See TracBrowser for help on using the repository browser.