source: osm/applications/editors/josm/nsis/josm.nsi@ 30517

Last change on this file since 30517 was 30517, checked in by donvip, 11 years ago

[josm_win_installer] fix #josm10241 - disable quicklaunch icon by default + need Java 7 minimum
File size: 16.5 KB
Line 
1;
2; josm.nsi
3;
4
5; Set the compression mechanism first.
6; If you get an error here, please update to at least NSIS 2.07!
7SetCompressor /SOLID lzma
8
9!define DEST "josm"
10
11; Used to refresh the display of file association
12!define SHCNE_ASSOCCHANGED 0x08000000
13!define SHCNF_IDLIST 0
14
15; Used to add associations between file extensions and JOSM
16!define OSM_ASSOC "josm-file"
17
18; ============================================================================
19; Header configuration
20; ============================================================================
21; The name of the installer
22!define PROGRAM_NAME "JOSM"
23
24Name "${PROGRAM_NAME} ${VERSION}"
25
26; The file to write
27OutFile "${DEST}-setup-${VERSION}.exe"
28
29XPStyle on
30
31Var /GLOBAL plugins
32
33; ============================================================================
34; Modern UI
35; ============================================================================
36
37!include "MUI.nsh"
38
39; Icon of installer and uninstaller
40!define MUI_ICON "logo.ico"
41!define MUI_UNICON "logo.ico"
42
43!define MUI_COMPONENTSPAGE_SMALLDESC
44!define MUI_FINISHPAGE_NOAUTOCLOSE
45!define MUI_UNFINISHPAGE_NOAUTOCLOSE
46!define MUI_WELCOMEFINISHPAGE_BITMAP "josm-nsis-brand.bmp"
47!define MUI_WELCOMEPAGE_TEXT $(JOSM_WELCOME_TEXT)
48
49!define MUI_FINISHPAGE_RUN "$INSTDIR\josm.exe"
50
51
52; ============================================================================
53; MUI Pages
54; ============================================================================
55
56!insertmacro MUI_PAGE_WELCOME
57!insertmacro MUI_PAGE_LICENSE "..\core\LICENSE"
58!insertmacro MUI_PAGE_COMPONENTS
59;Page custom DisplayAdditionalTasksPage
60!insertmacro MUI_PAGE_DIRECTORY
61!insertmacro MUI_PAGE_INSTFILES
62!insertmacro MUI_PAGE_FINISH
63
64!insertmacro MUI_UNPAGE_WELCOME
65!insertmacro MUI_UNPAGE_CONFIRM
66!insertmacro MUI_UNPAGE_COMPONENTS
67!insertmacro MUI_UNPAGE_INSTFILES
68!insertmacro MUI_UNPAGE_FINISH
69
70; ============================================================================
71; MUI Languages
72; ============================================================================
73
74 ;Remember the installer language
75 !define MUI_LANGDLL_REGISTRY_ROOT "HKLM"
76 !define MUI_LANGDLL_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM"
77 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
78
79 ;; English goes first because its the default. The rest are
80 ;; in alphabetical order (at least the strings actually displayed
81 ;; will be).
82
83 !insertmacro MUI_LANGUAGE "English"
84 !insertmacro MUI_LANGUAGE "French"
85 !insertmacro MUI_LANGUAGE "German"
86
87;--------------------------------
88;Translations
89
90 !define JOSM_DEFAULT_LANGFILE "locale\english.nsh"
91
92 !include "langmacros.nsh"
93
94 !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "ENGLISH" "locale\english.nsh"
95 !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "FRENCH" "locale\french.nsh"
96 !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "GERMAN" "locale\german.nsh"
97
98; Uninstall stuff
99!define MUI_UNCONFIRMPAGE_TEXT_TOP ${un.JOSM_UNCONFIRMPAGE_TEXT_TOP}
100
101; ============================================================================
102; Installation types
103; ============================================================================
104
105InstType "$(JOSM_FULL_INSTALL)"
106
107InstType "un.$(un.JOSM_DEFAULT_UNINSTALL)"
108InstType "un.$(un.JOSM_FULL_UNINSTALL)"
109
110; ============================================================================
111; Reserve Files
112; ============================================================================
113
114 ;Things that need to be extracted on first (keep these lines before any File command!)
115 ;Only useful for BZIP2 compression
116
117!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
118
119; ============================================================================
120; Section macros
121; ============================================================================
122!include "Sections.nsh"
123
124; ========= Macro to unselect and disable a section =========
125
126!macro DisableSection SECTION
127
128 Push $0
129 SectionGetFlags "${SECTION}" $0
130 IntOp $0 $0 & ${SECTION_OFF}
131 IntOp $0 $0 | ${SF_RO}
132 SectionSetFlags "${SECTION}" $0
133 Pop $0
134
135!macroend
136
137; ========= Macro to enable (unreadonly) a section =========
138!define SECTION_ENABLE 0xFFFFFFEF
139!macro EnableSection SECTION
140
141 Push $0
142 SectionGetFlags "${SECTION}" $0
143 IntOp $0 $0 & ${SECTION_ENABLE}
144 SectionSetFlags "${SECTION}" $0
145 Pop $0
146
147!macroend
148
149; ============================================================================
150; Command Line
151; ============================================================================
152!include "FileFunc.nsh"
153
154; ============================================================================
155; Directory selection page configuration
156; ============================================================================
157; The text to prompt the user to enter a directory
158DirText $(JOSM_DIR_TEXT)
159
160; The default installation directory
161InstallDir $PROGRAMFILES\JOSM\
162
163; See if this is an upgrade; if so, use the old InstallDir as default
164InstallDirRegKey HKEY_LOCAL_MACHINE SOFTWARE\JOSM "InstallDir"
165
166
167; ============================================================================
168; Install page configuration
169; ============================================================================
170ShowInstDetails show
171ShowUninstDetails show
172
173; ============================================================================
174; Functions and macros
175; ============================================================================
176
177; update file extension icons
178!macro UpdateIcons
179 Push $R0
180 Push $R1
181 Push $R2
182
183 !define UPDATEICONS_UNIQUE ${__LINE__}
184
185 IfFileExists "$SYSDIR\shell32.dll" UpdateIcons.next1_${UPDATEICONS_UNIQUE} UpdateIcons.error1_${UPDATEICONS_UNIQUE}
186UpdateIcons.next1_${UPDATEICONS_UNIQUE}:
187 GetDllVersion "$SYSDIR\shell32.dll" $R0 $R1
188 IntOp $R2 $R0 / 0x00010000
189 IntCmp $R2 4 UpdateIcons.next2_${UPDATEICONS_UNIQUE} UpdateIcons.error2_${UPDATEICONS_UNIQUE}
190UpdateIcons.next2_${UPDATEICONS_UNIQUE}:
191 System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
192 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
193
194UpdateIcons.error1_${UPDATEICONS_UNIQUE}:
195 MessageBox MB_OK|MB_ICONSTOP $(JOSM_UPDATEICONS_ERROR1)
196 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
197UpdateIcons.error2_${UPDATEICONS_UNIQUE}:
198 MessageBox MB_OK|MB_ICONINFORMATION $(JOSM_UPDATEICONS_ERROR2)
199 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
200UpdateIcons.quit_${UPDATEICONS_UNIQUE}:
201 !undef UPDATEICONS_UNIQUE
202 Pop $R2
203 Pop $R1
204 Pop $R0
205
206!macroend
207
208; associate a file extension to an icon
209Function Associate
210 ; $R0 should contain the prefix to associate to JOSM
211 Push $R1
212
213 ReadRegStr $R1 HKCR $R0 ""
214 StrCmp $R1 "" Associate.doRegister
215 Goto Associate.end
216Associate.doRegister:
217 ;The extension is not associated to any program, we can do the link
218 WriteRegStr HKCR $R0 "" ${OSM_ASSOC}
219Associate.end:
220 pop $R1
221FunctionEnd
222
223; disassociate a file extension from an icon
224Function un.unlink
225 ; $R0 should contain the prefix to unlink
226 Push $R1
227
228 ReadRegStr $R1 HKCR $R0 ""
229 StrCmp $R1 ${OSM_ASSOC} un.unlink.doUnlink
230 Goto un.unlink.end
231un.unlink.doUnlink:
232 ; The extension is associated with JOSM so, we must destroy this!
233 DeleteRegKey HKCR $R0
234un.unlink.end:
235 pop $R1
236FunctionEnd
237
238Function .onInit
239 ;Extract InstallOptions INI files
240; !insertmacro MUI_INSTALLOPTIONS_EXTRACT "AdditionalTasksPage.ini"
241 !insertmacro MUI_LANGDLL_DISPLAY
242FunctionEnd
243
244Function un.onInit
245
246 !insertmacro MUI_UNGETLANGUAGE
247
248FunctionEnd
249
250; ============================================================================
251; Installation execution commands
252; ============================================================================
253
254Section "-Required"
255;-------------------------------------------
256
257;
258; Install for every user
259;
260SectionIn 1 2 RO
261SetShellVarContext current
262
263SetOutPath $INSTDIR
264
265; Write the uninstall keys for Windows
266WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayVersion" "${VERSION}"
267WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayName" "JOSM ${VERSION}"
268WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "UninstallString" '"$INSTDIR\uninstall.exe"'
269WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "Publisher" "The OpenStreetMap developer community, http://www.openstreetmap.org/"
270WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "HelpLink" "mailto:newbies@openstreetmap.org."
271WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLInfoAbout" "http://www.openstreetmap.org/"
272WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLUpdateInfo" "http://wiki.openstreetmap.org/index.php/JOSM"
273WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoModify" 1
274WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoRepair" 1
275WriteUninstaller "uninstall.exe"
276
277; Write an entry for ShellExecute
278WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "" '$INSTDIR\josm.exe'
279WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "Path" '$INSTDIR'
280
281SectionEnd ; "Required"
282
283
284Section $(JOSM_SEC_JOSM) SecJosm
285;-------------------------------------------
286SectionIn 1
287SetOutPath $INSTDIR
288File "josm.exe"
289File "josm-tested.jar"
290
291; XXX - should be provided/done by josm.jar itself and not here!
292SetShellVarContext current
293SetOutPath "$APPDATA\JOSM"
294
295SectionEnd
296
297SectionGroup $(JOSM_SEC_PLUGINS_GROUP) SecPluginsGroup
298
299Section $(JOSM_SEC_TURNRESTRICTIONS_PLUGIN) SecTurnrestrictionsPlugin
300;-------------------------------------------
301SectionIn 1 2
302SetShellVarContext current
303SetOutPath $APPDATA\JOSM\plugins
304File "..\dist\turnrestrictions.jar"
305StrCpy $plugins "$plugins<entry value='turnrestrictions'/>"
306SectionEnd
307
308Section $(JOSM_SEC_WMS) SecWMS
309;-------------------------------------------
310SectionIn 1 2
311SetShellVarContext current
312SetOutPath $INSTDIR\imageformats
313File "webkit-image\imageformats\qjpeg4.dll"
314SetOutPath $INSTDIR
315File "webkit-image\mingwm10.dll"
316File "webkit-image\QtCore4.dll"
317File "webkit-image\QtGui4.dll"
318File "webkit-image\QtNetwork4.dll"
319File "webkit-image\QtWebKit4.dll"
320File "webkit-image\webkit-image.exe"
321SectionEnd
322
323SectionGroupEnd ; "Plugins"
324
325Section $(JOSM_SEC_STARTMENU) SecStartMenu
326;-------------------------------------------
327SectionIn 1 2
328; To quote "http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dnwue/html/ch11d.asp":
329; "Do not include Readme, Help, or Uninstall entries on the Programs menu."
330CreateShortCut "$SMPROGRAMS\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
331SectionEnd
332
333Section $(JOSM_SEC_DESKTOP_ICON) SecDesktopIcon
334;-------------------------------------------
335; Create desktop icon
336; Desktop icon for a program should not be installed as default!
337CreateShortCut "$DESKTOP\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
338SectionEnd
339
340Section $(JOSM_SEC_QUICKLAUNCH_ICON) SecQuickLaunchIcon
341;-------------------------------------------
342; Create quick launch icon. Does not really exist as of Windows 7/8 but still advanced users use it.
343; Only disable it by default, see #10241
344CreateShortCut "$QUICKLAUNCH\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
345SectionEnd
346
347Section $(JOSM_SEC_FILE_EXTENSIONS) SecFileExtensions
348;-------------------------------------------
349SectionIn 1 2
350; Create File Extensions
351WriteRegStr HKCR ${OSM_ASSOC} "" "OpenStreetMap data"
352WriteRegStr HKCR "${OSM_ASSOC}\Shell\open\command" "" '"$INSTDIR\josm.exe" "%1"'
353WriteRegStr HKCR "${OSM_ASSOC}\DefaultIcon" "" '"$INSTDIR\josm.exe",0'
354push $R0
355 StrCpy $R0 ".osm"
356 Call Associate
357 StrCpy $R0 ".gpx"
358 Call Associate
359; if somethings added here, add it also to the uninstall section
360pop $R0
361!insertmacro UpdateIcons
362SectionEnd
363
364
365Section "-PluginSetting"
366;-------------------------------------------
367SectionIn 1 2
368;MessageBox MB_OK "PluginSetting!" IDOK 0
369; XXX - should better be handled inside JOSM (recent plugin manager is going in the right direction)
370SetShellVarContext current
371!include LogicLib.nsh
372IfFileExists "$APPDATA\JOSM\preferences" settings_exists
373IfFileExists "$APPDATA\JOSM\preferences.xml" settings_exists
374FileOpen $R0 "$APPDATA\JOSM\preferences.xml" w
375FileWrite $R0 "<?xml version='1.0' encoding='UTF-8'?><preferences xmlns='http://josm.openstreetmap.de/preferences-1.0' version='4660'><list key='plugins'>$plugins</list></preferences>"
376FileClose $R0
377settings_exists:
378
379SectionEnd
380
381
382Section "un.$(un.JOSM_SEC_UNINSTALL)" un.SecUinstall
383;-------------------------------------------
384
385;
386; UnInstall for every user
387;
388SectionIn 1 2
389SetShellVarContext current
390
391Delete "$INSTDIR\josm-tested.jar"
392IfErrors 0 NoJOSMErrorMsg
393 MessageBox MB_OK $(un.JOSM_IN_USE_ERROR) IDOK 0 ;skipped if josm.jar removed
394 Abort $(un.JOSM_IN_USE_ERROR)
395NoJOSMErrorMsg:
396Delete "$INSTDIR\josm.exe"
397Delete "$INSTDIR\imageformats\qjpeg4.dll"
398RMDir "$INSTDIR\imageformats"
399Delete "$INSTDIR\mingwm10.dll"
400Delete "$INSTDIR\QtCore4.dll"
401Delete "$INSTDIR\QtGui4.dll"
402Delete "$INSTDIR\QtNetwork4.dll"
403Delete "$INSTDIR\QtWebKit4.dll"
404Delete "$INSTDIR\webkit-image.exe"
405Delete "$INSTDIR\uninstall.exe"
406
407DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM"
408DeleteRegKey HKEY_LOCAL_MACHINE "Software\josm.exe"
409DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe"
410
411; Remove Language preference info
412DeleteRegKey HKCU "Software/JOSM" ;${MUI_LANGDLL_REGISTRY_ROOT} ${MUI_LANGDLL_REGISTRY_KEY}
413
414push $R0
415 StrCpy $R0 ".osm"
416 Call un.unlink
417 StrCpy $R0 ".gpx"
418 Call un.unlink
419pop $R0
420
421DeleteRegKey HKCR ${OSM_ASSOC}
422DeleteRegKey HKCR "${OSM_ASSOC}\Shell\open\command"
423DeleteRegKey HKCR "${OSM_ASSOC}\DefaultIcon"
424!insertmacro UpdateIcons
425
426Delete "$SMPROGRAMS\josm.lnk"
427Delete "$DESKTOP\josm.lnk"
428Delete "$QUICKLAUNCH\josm.lnk"
429
430RMDir "$INSTDIR"
431
432SectionEnd ; "Uninstall"
433
434Section /o "un.$(un.JOSM_SEC_PERSONAL_SETTINGS)" un.SecPersonalSettings
435;-------------------------------------------
436SectionIn 2
437SetShellVarContext current
438Delete "$APPDATA\JOSM\plugins\turnrestrictions\*.*"
439RMDir "$APPDATA\JOSM\plugins\turnrestrictions"
440Delete "$APPDATA\JOSM\plugins\openstreetbugs\*.*"
441RMDir "$APPDATA\JOSM\plugins\openstreetbugs"
442Delete "$APPDATA\JOSM\plugins\*.*"
443RMDir "$APPDATA\JOSM\plugins"
444
445Delete "$APPDATA\JOSM\motd.html"
446Delete "$APPDATA\JOSM\preferences.xml"
447RMDir "$APPDATA\JOSM"
448SectionEnd
449
450
451Section "-Un.Finally"
452;-------------------------------------------
453SectionIn 1 2
454; this test must be done after all other things uninstalled (e.g. Global Settings)
455IfFileExists "$INSTDIR" 0 NoFinalErrorMsg
456 MessageBox MB_OK $(un.JOSM_INSTDIR_ERROR) IDOK 0 ; skipped if dir doesn't exist
457NoFinalErrorMsg:
458SectionEnd
459
460
461; ============================================================================
462; PLEASE MAKE SURE, THAT THE DESCRIPTIVE TEXT FITS INTO THE DESCRIPTION FIELD!
463; ============================================================================
464!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
465 !insertmacro MUI_DESCRIPTION_TEXT ${SecJosm} $(JOSM_SECDESC_JOSM)
466 !insertmacro MUI_DESCRIPTION_TEXT ${SecPluginsGroup} $(JOSM_SECDESC_PLUGINS_GROUP)
467 !insertmacro MUI_DESCRIPTION_TEXT ${SecTurnrestrictionsPlugin} $(JOSM_SECDESC_TURNRESTRICTIONS_PLUGIN)
468 !insertmacro MUI_DESCRIPTION_TEXT ${SecWMS} $(JOSM_SECDESC_WMS)
469 !insertmacro MUI_DESCRIPTION_TEXT ${SecStartMenu} $(JOSM_SECDESC_STARTMENU)
470 !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktopIcon} $(JOSM_SECDESC_DESKTOP_ICON)
471 !insertmacro MUI_DESCRIPTION_TEXT ${SecQuickLaunchIcon} $(JOSM_SECDESC_QUICKLAUNCH_ICON)
472 !insertmacro MUI_DESCRIPTION_TEXT ${SecFileExtensions} $(JOSM_SECDESC_FILE_EXTENSIONS)
473
474
475!insertmacro MUI_FUNCTION_DESCRIPTION_END
476
477!insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
478 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUinstall} $(un.JOSM_SECDESC_UNINSTALL)
479 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecPersonalSettings} $(un.JOSM_SECDESC_PERSONAL_SETTINGS)
480!insertmacro MUI_UNFUNCTION_DESCRIPTION_END
481
482; ============================================================================
483; Callback functions
484; ============================================================================
485
Note: See TracBrowser for help on using the repository browser.