source: josm/trunk/scripts/SyncEditorLayerIndex.groovy @ 11612

Last change on this file since 11612 was 11612, checked in by stoecker, 14 months ago

add dates with open timespan

  • Property svn:eol-style set to native
File size: 22.0 KB
Line 
1// License: GPL. For details, see LICENSE file.
2/**
3 * Compare and analyse the differences of the editor imagery index and the JOSM imagery list.
4 * The goal is to keep both lists in sync.
5 *
6 * The editor imagery index project (https://github.com/osmlab/editor-imagery-index)
7 * provides also a version in the JOSM format, but the JSON is the original source
8 * format, so we read that.
9 *
10 * How to run:
11 * -----------
12 *
13 * Main JOSM binary needs to be in classpath, e.g.
14 *
15 * $ groovy -cp ../dist/josm-custom.jar SyncEditorImageryIndex.groovy
16 *
17 * Add option "-h" to show the available command line flags.
18 */
19import javax.json.Json
20import javax.json.JsonArray
21import javax.json.JsonObject
22import javax.json.JsonReader
23import javax.json.JsonValue
24
25import org.openstreetmap.josm.data.imagery.ImageryInfo
26import org.openstreetmap.josm.data.imagery.Shape
27import org.openstreetmap.josm.io.imagery.ImageryReader
28
29class SyncEditorImageryIndex {
30
31    List<ImageryInfo> josmEntries;
32    JsonArray eliEntries;
33
34    def eliUrls = new HashMap<String, JsonObject>()
35    def josmUrls = new HashMap<String, ImageryInfo>()
36    def josmMirrors = new HashMap<String, ImageryInfo>()
37
38    static String eliInputFile = 'imagery.geojson'
39    static String josmInputFile = 'maps.xml'
40    static String ignoreInputFile = 'maps_ignores.txt'
41    static FileWriter outputFile = null
42    static BufferedWriter outputStream = null
43    def skip = [:]
44
45    static def options
46
47    /**
48     * Main method.
49     */
50    static main(def args) {
51        parse_command_line_arguments(args)
52        def script = new SyncEditorImageryIndex()
53        script.loadSkip()
54        script.start()
55        script.loadJosmEntries()
56        script.loadELIEntries()
57        script.checkInOneButNotTheOther()
58        script.checkCommonEntries()
59        script.end()
60        if(outputStream != null) {
61            outputStream.close();
62        }
63        if(outputFile != null) {
64            outputFile.close();
65        }
66    }
67
68    /**
69     * Parse command line arguments.
70     */
71    static void parse_command_line_arguments(args) {
72        def cli = new CliBuilder(width: 160)
73        cli.o(longOpt:'output', args:1, argName: "output", "Output file, - prints to stdout (default: -)")
74        cli.e(longOpt:'eli_input', args:1, argName:"eli_input", "Input file for the editor imagery index (json). Default is $eliInputFile (current directory).")
75        cli.j(longOpt:'josm_input', args:1, argName:"josm_input", "Input file for the JOSM imagery list (xml). Default is $josmInputFile (current directory).")
76        cli.i(longOpt:'ignore_input', args:1, argName:"ignore_input", "Input file for the ignore list. Default is $ignoreInputFile (current directory).")
77        cli.s(longOpt:'shorten', "shorten the output, so it is easier to read in a console window")
78        cli.n(longOpt:'noskip', argName:"noskip", "don't skip known entries")
79        cli.x(longOpt:'xhtmlbody', argName:"xhtmlbody", "create XHTML body for display in a web page")
80        cli.X(longOpt:'xhtml', argName:"xhtml", "create XHTML for display in a web page")
81        cli.m(longOpt:'nomissingeli', argName:"nomissingeli", "don't show missing editor imagery index entries")
82        cli.h(longOpt:'help', "show this help")
83        options = cli.parse(args)
84
85        if (options.h) {
86            cli.usage()
87            System.exit(0)
88        }
89        if (options.eli_input) {
90            eliInputFile = options.eli_input
91        }
92        if (options.josm_input) {
93            josmInputFile = options.josm_input
94        }
95        if (options.ignore_input) {
96            ignoreInputFile = options.ignore_input
97        }
98        if (options.output && options.output != "-") {
99            outputFile = new FileWriter(options.output)
100            outputStream = new BufferedWriter(outputFile)
101        }
102    }
103
104    void loadSkip() {
105        FileReader fr = new FileReader(ignoreInputFile)
106        def line
107
108        while((line = fr.readLine()) != null) {
109            def res = (line =~ /^\|\| *(ELI|Ignore) *\|\| *\{\{\{(.+)\}\}\} *\|\|/)
110            if(res.count)
111            {
112                if(res[0][1].equals("Ignore")) {
113                    skip[res[0][2]] = "green"
114                } else {
115                    skip[res[0][2]] = "darkgoldenrod"
116                }
117            }
118        }
119    }
120
121    void myprintlnfinal(String s) {
122        if(outputStream != null) {
123            outputStream.write(s);
124            outputStream.newLine();
125        } else {
126            println s;
127        }
128    }
129
130    void myprintln(String s) {
131        if(skip.containsKey(s)) {
132            String color = skip.get(s)
133            skip.remove(s)
134            if(options.xhtmlbody || options.xhtml) {
135                s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
136            }
137            if (!options.noskip) {
138                return;
139            }
140        } else if(options.xhtmlbody || options.xhtml) {
141            String color = s.startsWith("***") ? "black" : ((s.startsWith("+ ") || s.startsWith("+++ ELI")) ? "blue" : "red")
142            s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
143        }
144        myprintlnfinal(s)
145    }
146
147    void start() {
148        if (options.xhtml) {
149            myprintlnfinal "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">\n"
150            myprintlnfinal "<html><head><meta http-equiv=\"Content-Type\" content=\"text/html; charset=UTF-8\"/><title>JOSM - ELI differences</title></head><body>\n"
151        }
152    }
153
154    void end() {
155        for (def s: skip.keySet()) {
156            myprintln "+++ Obsolete skip entry: " + s
157        }
158        if (options.xhtml) {
159            myprintlnfinal "</body></html>\n"
160        }
161    }
162
163    void loadELIEntries() {
164        FileReader fr = new FileReader(eliInputFile)
165        JsonReader jr = Json.createReader(fr)
166        eliEntries = jr.readObject().get("features")
167        jr.close()
168
169        for (def e : eliEntries) {
170            def url = getUrl(e)
171            if (url.contains("{z}")) {
172                myprintln "+++ ELI-URL uses {z} instead of {zoom}: "+url
173                url = url.replace("{z}","{zoom}")
174            }
175            if (eliUrls.containsKey(url)) {
176                myprintln "+++ ELI-URL is not unique: "+url
177            } else {
178                eliUrls.put(url, e)
179            }
180        }
181        myprintln "*** Loaded ${eliEntries.size()} entries (ELI). ***"
182    }
183
184    void loadJosmEntries() {
185        def reader = new ImageryReader(josmInputFile)
186        josmEntries = reader.parse()
187
188        for (def e : josmEntries) {
189            def url = getUrl(e)
190            if (url.contains("{z}")) {
191                myprintln "+++ JOSM-URL uses {z} instead of {zoom}: "+url
192                url = url.replace("{z}","{zoom}")
193            }
194            if (josmUrls.containsKey(url)) {
195                myprintln "+++ JOSM-URL is not unique: "+url
196            } else {
197                josmUrls.put(url, e)
198            }
199            for (def m : e.getMirrors()) {
200                url = getUrl(m)
201                m.origName = m.getOriginalName().replaceAll(" mirror server( \\d+)?","")
202                if (josmUrls.containsKey(url)) {
203                    myprintln "+++ JOSM-Mirror-URL is not unique: "+url
204                } else {
205                    josmUrls.put(url, m)
206                    josmMirrors.put(url, m)
207                }
208            }
209        }
210        myprintln "*** Loaded ${josmEntries.size()} entries (JOSM). ***"
211    }
212
213    List inOneButNotTheOther(Map m1, Map m2) {
214        def l = []
215        for (def url : m1.keySet()) {
216            if (!m2.containsKey(url)) {
217                def name = getName(m1.get(url))
218                l += "  "+getDescription(m1.get(url))
219            }
220        }
221        l.sort()
222    }
223
224    void checkInOneButNotTheOther() {
225        def l1 = inOneButNotTheOther(eliUrls, josmUrls)
226        myprintln "*** URLs found in ELI but not in JOSM (${l1.size()}): ***"
227        if (!l1.isEmpty()) {
228            for (def l : l1) {
229                myprintln "-" + l
230            }
231        }
232
233        if (options.nomissingeli)
234            return
235        def l2 = inOneButNotTheOther(josmUrls, eliUrls)
236        myprintln "*** URLs found in JOSM but not in ELI (${l2.size()}): ***"
237        if (!l2.isEmpty()) {
238            for (def l : l2) {
239                myprintln "+" + l
240            }
241        }
242    }
243
244    void checkCommonEntries() {
245        myprintln "*** Same URL, but different name: ***"
246        for (def url : eliUrls.keySet()) {
247            def e = eliUrls.get(url)
248            if (!josmUrls.containsKey(url)) continue
249            def j = josmUrls.get(url)
250            if (!getName(e).equals(getName(j))) {
251                myprintln "* Name differs ('${getName(e)}' != '${getName(j)}'): $url"
252            }
253        }
254
255        myprintln "*** Same URL, but different type: ***"
256        for (def url : eliUrls.keySet()) {
257            def e = eliUrls.get(url)
258            if (!josmUrls.containsKey(url)) continue
259            def j = josmUrls.get(url)
260            if (!getType(e).equals(getType(j))) {
261                myprintln "* Type differs (${getType(e)} != ${getType(j)}): ${getName(j)} - $url"
262            }
263        }
264
265        myprintln "*** Same URL, but different zoom bounds: ***"
266        for (def url : eliUrls.keySet()) {
267            def e = eliUrls.get(url)
268            if (!josmUrls.containsKey(url)) continue
269            def j = josmUrls.get(url)
270
271            Integer eMinZoom = getMinZoom(e)
272            Integer jMinZoom = getMinZoom(j)
273            if (eMinZoom != jMinZoom  && !(eMinZoom == 0 && jMinZoom == null)) {
274                myprintln "* Minzoom differs (${eMinZoom} != ${jMinZoom}): ${getDescription(j)}"
275            }
276            Integer eMaxZoom = getMaxZoom(e)
277            Integer jMaxZoom = getMaxZoom(j)
278            if (eMaxZoom != jMaxZoom) {
279                myprintln "* Maxzoom differs (${eMaxZoom} != ${jMaxZoom}): ${getDescription(j)}"
280            }
281        }
282
283        myprintln "*** Same URL, but different country code: ***"
284        for (def url : eliUrls.keySet()) {
285            def e = eliUrls.get(url)
286            if (!josmUrls.containsKey(url)) continue
287            def j = josmUrls.get(url)
288            if (!getCountryCode(e).equals(getCountryCode(j))) {
289                myprintln "* Country code differs (${getCountryCode(e)} != ${getCountryCode(j)}): ${getDescription(j)}"
290            }
291        }
292        myprintln "*** Same URL, but different quality: ***"
293        for (def url : eliUrls.keySet()) {
294            def e = eliUrls.get(url)
295            if (!josmUrls.containsKey(url)) {
296              def q = getQuality(e)
297              if("eli-best".equals(q)) {
298                myprintln "- Quality best entry not in JOSM for ${getDescription(e)}"
299              }
300              continue
301            }
302            def j = josmUrls.get(url)
303            if (!getQuality(e).equals(getQuality(j))) {
304                myprintln "* Quality differs (${getQuality(e)} != ${getQuality(j)}): ${getDescription(j)}"
305            }
306        }
307        /*myprintln "*** Same URL, but different dates: ***"
308        for (def url : eliUrls.keySet()) {
309            def ed = getDate(eliUrls.get(url))
310            if (!josmUrls.containsKey(url)) continue
311            def j = josmUrls.get(url)
312            def jd = getDate(j)
313            // The forms 2015;- or -;2015 or 2015;2015 are handled equal to 2015
314            String ef = ed.replaceAll("\\A-;","").replaceAll(";-\\z","").replaceAll("\\A([0-9-]+);\\1\\z","\$1");
315            if (!ed.equals(jd) && !ef.equals(jd)) {
316                String t = "'${ed}'";
317                if (!ed.equals(ef)) {
318                    t += "or '${ef}'";
319                }
320                myprintln "* Date differs (${t} != '${jd}'): ${getDescription(j)}"
321            }
322        }*/
323        myprintln "*** Mismatching shapes: ***"
324        for (def url : josmUrls.keySet()) {
325            def j = josmUrls.get(url)
326            def num = 1
327            for (def shape : getShapes(j)) {
328                def p = shape.getPoints()
329                if(!p[0].equals(p[p.size()-1])) {
330                    myprintln "+++ JOSM shape $num unclosed: ${getDescription(j)}"
331                }
332                ++num
333            }
334        }
335        for (def url : eliUrls.keySet()) {
336            def e = eliUrls.get(url)
337            def num = 1
338            def s = getShapes(e)
339            for (def shape : s) {
340                def p = shape.getPoints()
341                if(!p[0].equals(p[p.size()-1]) && !options.nomissingeli) {
342                    myprintln "+++ ELI shape $num unclosed: ${getDescription(e)}"
343                }
344                ++num
345            }
346            if (!josmUrls.containsKey(url)) {
347                continue
348            }
349            def j = josmUrls.get(url)
350            def js = getShapes(j)
351            if(!s.size() && js.size()) {
352                if(!options.nomissingeli) {
353                    myprintln "+ No ELI shape: ${getDescription(j)}"
354                }
355            } else if(!js.size() && s.size()) {
356                // don't report boundary like 5 point shapes as difference
357                if (s.size() != 1 || s[0].getPoints().size() != 5) {
358                    myprintln "- No JOSM shape: ${getDescription(j)}"
359                }
360            } else if(s.size() != js.size()) {
361                myprintln "* Different number of shapes (${s.size()} != ${js.size()}): ${getDescription(j)}"
362            } else {
363                for(def nums = 0; nums < s.size(); ++nums) {
364                    def ep = s[nums].getPoints()
365                    def jp = js[nums].getPoints()
366                    if(ep.size() != jp.size()) {
367                        myprintln "* Different number of points for shape ${nums+1} (${ep.size()} ! = ${jp.size()})): ${getDescription(j)}"
368                    } else {
369                        for(def nump = 0; nump < ep.size(); ++nump) {
370                            def ept = ep[nump]
371                            def jpt = jp[nump]
372                            if(Math.abs(ept.getLat()-jpt.getLat()) > 0.000001 || Math.abs(ept.getLon()-jpt.getLon()) > 0.000001) {
373                                myprintln "* Different coordinate for point ${nump+1} of shape ${nums+1}: ${getDescription(j)}"
374                                nump = ep.size()
375                                num = s.size()
376                            }
377                        }
378                    }
379                }
380            }
381        }
382        myprintln "*** Mismatching icons: ***"
383        for (def url : eliUrls.keySet()) {
384            def e = eliUrls.get(url)
385            if (!josmUrls.containsKey(url)) {
386                continue
387            }
388            def j = josmUrls.get(url)
389            def ij = getIcon(j)
390            def ie = getIcon(e)
391            if(ij != null && ie == null) {
392                if(!options.nomissingeli) {
393                    myprintln "+ No ELI icon: ${getDescription(j)}"
394                }
395            } else if(ij == null && ie != null) {
396                myprintln "- No JOSM icon: ${getDescription(j)}"
397            } else if(!ij.equals(ie)) {
398                myprintln "* Different icons: ${getDescription(j)}"
399            }
400        }
401        myprintln "*** Miscellaneous checks: ***"
402        def josmIds = new HashMap<String, ImageryInfo>()
403        for (def url : josmUrls.keySet()) {
404            def j = josmUrls.get(url)
405            def id = getId(j)
406            if(josmMirrors.containsKey(url)) {
407                continue;
408            }
409            if(id == null) {
410                myprintln "* No JOSM-ID: ${getDescription(j)}"
411            } else if(josmIds.containsKey(id)) {
412                myprintln "* JOSM-ID ${id} not unique: ${getDescription(j)}"
413            } else {
414                josmIds.put(id, j);
415            }
416            def d = getDate(j)
417            if(!d.isEmpty()) {
418                def reg = (d =~ /^(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?)(;(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?))?/)
419                if(reg == null || reg.count != 1) {
420                    myprintln "* JOSM-Date '${d}' is strange: ${getDescription(j)}"
421                } else {
422                    try {
423                        def first = verifyDate(reg[0][2],reg[0][4],reg[0][6]);
424                        def second = verifyDate(reg[0][9],reg[0][11],reg[0][13]);
425                        if(second.compareTo(first) < 0) {
426                            myprintln "* JOSM-Date '${d}' is strange (second earlier than first): ${getDescription(j)}"
427                        }
428                    }
429                    catch (Exception e) {
430                        myprintln "* JOSM-Date '${d}' is strange (${e.getMessage()}): ${getDescription(j)}"
431                    }
432                }
433            }
434            def js = getShapes(j)
435            if(js.size()) {
436                def minlat = 1000;
437                def minlon = 1000;
438                def maxlat = -1000;
439                def maxlon = -1000;
440                for(def s: js) {
441                    for(def p: s.getPoints()) {
442                        def lat = p.getLat();
443                        def lon = p.getLon();
444                        if(lat > maxlat) maxlat = lat;
445                        if(lon > maxlon) maxlon = lon;
446                        if(lat < minlat) minlat = lat;
447                        if(lon < minlon) minlon = lon;
448                    }
449                }
450                def b = j.getBounds();
451                if(b.getMinLat() != minlat || b.getMinLon() != minlon || b.getMaxLat() != maxlat || b.getMaxLon() != maxlon) {
452                    myprintln "* Bounds do not match shape (is ${b.getMinLat()},${b.getMinLon()},${b.getMaxLat()},${b.getMaxLon()}, calculated <bounds min-lat='${minlat}' min-lon='${minlon}' max-lat='${maxlat}' max-lon='${maxlon}'>): ${getDescription(j)}"
453                }
454            }
455        }
456    }
457
458    /**
459     * Utility functions that allow uniform access for both ImageryInfo and JsonObject.
460     */
461    static String getUrl(Object e) {
462        if (e instanceof ImageryInfo) return e.url
463        return e.get("properties").getString("url")
464    }
465    static String getDate(Object e) {
466        if (e instanceof ImageryInfo) return e.date ? e.date : ""
467        def p = e.get("properties")
468        def start = p.containsKey("start_date") ? p.getString("start_date") : ""
469        def end = p.containsKey("end_date") ? p.getString("end_date") : ""
470        if(!start.isEmpty() && !end.isEmpty())
471            return start+";"+end
472        else if(!start.isEmpty())
473            return start+";-"
474        else if(!end.isEmpty())
475            return "-;"+end
476        return "";
477    }
478    static Date verifyDate(String year, String month, String day) {
479        def date
480        if(year == null)
481            date = "3000-01-01"
482        else
483            date = year + "-" + (month == null ? "01" : month) + "-" + (day == null ? "01" : day)
484        def df = new java.text.SimpleDateFormat("yyyy-MM-dd")
485        df.setLenient(false)
486        return df.parse(date)
487    }
488    static String getId(Object e) {
489        if (e instanceof ImageryInfo) return e.getId()
490        return e.get("properties").getString("id")
491    }
492    static String getName(Object e) {
493        if (e instanceof ImageryInfo) return e.getOriginalName()
494        return e.get("properties").getString("name")
495    }
496    static List<Shape> getShapes(Object e) {
497        if (e instanceof ImageryInfo) {
498            def bounds = e.getBounds();
499            if(bounds != null) {
500                return bounds.getShapes();
501            }
502            return []
503        }
504        if(!e.isNull("geometry")) {
505            def ex = e.get("geometry")
506            if(ex != null && !ex.isNull("coordinates")) {
507                def poly = ex.get("coordinates")
508                List<Shape> l = []
509                for(def shapes: poly) {
510                    def s = new Shape()
511                    for(def point: shapes) {
512                        def lon = point[0].toString()
513                        def lat = point[1].toString()
514                        s.addPoint(lat, lon)
515                    }
516                    l.add(s)
517                }
518                return l
519            }
520        }
521        return []
522    }
523    static String getType(Object e) {
524        if (e instanceof ImageryInfo) return e.getImageryType().getTypeString()
525        return e.get("properties").getString("type")
526    }
527    static Integer getMinZoom(Object e) {
528        if (e instanceof ImageryInfo) {
529            int mz = e.getMinZoom()
530            return mz == 0 ? null : mz
531        } else {
532            def num = e.get("properties").getJsonNumber("min_zoom")
533            if (num == null) return null
534            return num.intValue()
535        }
536    }
537    static Integer getMaxZoom(Object e) {
538        if (e instanceof ImageryInfo) {
539            int mz = e.getMaxZoom()
540            return mz == 0 ? null : mz
541        } else {
542            def num = e.get("properties").getJsonNumber("max_zoom")
543            if (num == null) return null
544            return num.intValue()
545        }
546    }
547    static String getCountryCode(Object e) {
548        if (e instanceof ImageryInfo) return "".equals(e.getCountryCode()) ? null : e.getCountryCode()
549        return e.get("properties").getString("country_code", null)
550    }
551    static String getQuality(Object e) {
552        if (e instanceof ImageryInfo) return e.isBestMarked() ? "eli-best" : null
553        return (e.get("properties").containsKey("best")
554            && e.get("properties").getBoolean("best")) ? "eli-best" : null
555    }
556    static String getIcon(Object e) {
557        if (e instanceof ImageryInfo) return e.getIcon()
558        return e.get("properties").getString("icon", null)
559    }
560    String getDescription(Object o) {
561        def url = getUrl(o)
562        def cc = getCountryCode(o)
563        if (cc == null) {
564            def j = josmUrls.get(url)
565            if (j != null) cc = getCountryCode(j)
566            if (cc == null) {
567                def e = eliUrls.get(url)
568                if (e != null) cc = getCountryCode(e)
569            }
570        }
571        if (cc == null) {
572            cc = ''
573        } else {
574            cc = "[$cc] "
575        }
576        def d = cc + getName(o) + " - " + getUrl(o)
577        if (options.shorten) {
578            def MAXLEN = 140
579            if (d.length() > MAXLEN) d = d.substring(0, MAXLEN-1) + "..."
580        }
581        return d
582    }
583}
Note: See TracBrowser for help on using the repository browser.