source: josm/trunk/windows/josm.nsi @ 7849

Last change on this file since 7849 was 7849, checked in by Don-vip, 9 years ago

fix windows installer script
File size: 16.3 KB
Line 
1;
2; josm.nsi
3;
4
5; Set the compression mechanism first.
6SetCompressor /SOLID lzma
7
8; Load StdUtils plugin (ANSI until we switch to Unicode installer with NSIS 3)
9!addplugindir plugins/stdutils/Plugins/Release_ANSI
10!addincludedir plugins/stdutils/Include
11
12!include "StdUtils.nsh"
13
14; make sure the installer will get elevated rights on UAC-enabled system (Vista+)
15RequestExecutionLevel admin
16
17; Used to refresh the display of file association
18!define SHCNE_ASSOCCHANGED 0x08000000
19!define SHCNF_IDLIST 0
20
21; Used to add associations between file extensions and JOSM
22!define OSM_ASSOC "josm-file"
23
24; ============================================================================
25; Header configuration
26; ============================================================================
27; The name of the installer
28Name "JOSM ${VERSION}"
29
30; The file to write
31OutFile "${DEST}-setup-${VERSION}.exe"
32
33XPStyle on
34
35Var /GLOBAL plugins
36
37; ============================================================================
38; Modern UI
39; ============================================================================
40
41!include "MUI2.nsh"
42
43; Icon of installer and uninstaller
44!define MUI_ICON "logo.ico"
45!define MUI_UNICON "logo.ico"
46
47!define MUI_COMPONENTSPAGE_SMALLDESC
48!define MUI_FINISHPAGE_NOAUTOCLOSE
49!define MUI_UNFINISHPAGE_NOAUTOCLOSE
50!define MUI_WELCOMEFINISHPAGE_BITMAP "josm-nsis-brand.bmp"
51!define MUI_WELCOMEPAGE_TEXT $(JOSM_WELCOME_TEXT)
52
53!define MUI_FINISHPAGE_RUN
54!define MUI_FINISHPAGE_RUN_FUNCTION LaunchJOSM
55
56; Function used to Launch JOSM in user (non-elevated) mode
57Function LaunchJOSM
58  ${StdUtils.ExecShellAsUser} $0 "$INSTDIR\${DEST}.exe" "open" ""
59FunctionEnd
60
61; ============================================================================
62; MUI Pages
63; ============================================================================
64
65!insertmacro MUI_PAGE_WELCOME
66!insertmacro MUI_PAGE_LICENSE "..\LICENSE"
67!insertmacro MUI_PAGE_COMPONENTS
68!insertmacro MUI_PAGE_DIRECTORY
69!insertmacro MUI_PAGE_INSTFILES
70!insertmacro MUI_PAGE_FINISH
71
72!insertmacro MUI_UNPAGE_WELCOME
73!insertmacro MUI_UNPAGE_CONFIRM
74!insertmacro MUI_UNPAGE_COMPONENTS
75!insertmacro MUI_UNPAGE_INSTFILES
76!insertmacro MUI_UNPAGE_FINISH
77
78; ============================================================================
79; MUI Languages
80; ============================================================================
81
82  ;Remember the installer language
83  !define MUI_LANGDLL_REGISTRY_ROOT "HKLM" 
84  !define MUI_LANGDLL_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" 
85  !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
86 
87  ;; English goes first because its the default. The rest are
88  ;; in alphabetical order (at least the strings actually displayed
89  ;; will be).
90
91  !insertmacro MUI_LANGUAGE "English"
92  !insertmacro MUI_LANGUAGE "French"
93  !insertmacro MUI_LANGUAGE "German"
94
95;--------------------------------
96;Translations
97
98  !define JOSM_DEFAULT_LANGFILE "locale\english.nsh"
99
100  !include "langmacros.nsh"
101 
102  !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "ENGLISH" "locale\english.nsh"
103  !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "FRENCH" "locale\french.nsh"
104  !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "GERMAN" "locale\german.nsh"
105
106; Uninstall stuff
107!define MUI_UNCONFIRMPAGE_TEXT_TOP ${un.JOSM_UNCONFIRMPAGE_TEXT_TOP}
108
109; ============================================================================
110; Installation types
111; ============================================================================
112
113InstType "$(JOSM_FULL_INSTALL)"
114
115InstType "un.$(un.JOSM_DEFAULT_UNINSTALL)"
116InstType "un.$(un.JOSM_FULL_UNINSTALL)"
117
118; ============================================================================
119; Section macros
120; ============================================================================
121!include "Sections.nsh"
122
123; ========= Macro to unselect and disable a section =========
124
125!macro DisableSection SECTION
126
127  Push $0
128    SectionGetFlags "${SECTION}" $0
129    IntOp $0 $0 & ${SECTION_OFF}
130    IntOp $0 $0 | ${SF_RO}
131    SectionSetFlags "${SECTION}" $0
132  Pop $0
133
134!macroend
135
136; ========= Macro to enable (unreadonly) a section =========
137!define SECTION_ENABLE   0xFFFFFFEF
138!macro EnableSection SECTION
139
140  Push $0
141    SectionGetFlags "${SECTION}" $0
142    IntOp $0 $0 & ${SECTION_ENABLE}
143    SectionSetFlags "${SECTION}" $0
144  Pop $0
145
146!macroend
147
148; ============================================================================
149; Command Line
150; ============================================================================
151!include "FileFunc.nsh"
152
153; ============================================================================
154; Directory selection page configuration
155; ============================================================================
156; The text to prompt the user to enter a directory
157DirText $(JOSM_DIR_TEXT)
158
159; The default installation directory
160InstallDir $PROGRAMFILES\JOSM\
161
162; See if this is an upgrade; if so, use the old InstallDir as default
163InstallDirRegKey HKEY_LOCAL_MACHINE SOFTWARE\JOSM "InstallDir"
164
165
166; ============================================================================
167; Install page configuration
168; ============================================================================
169ShowInstDetails show
170ShowUninstDetails show
171
172; ============================================================================
173; Functions and macros
174; ============================================================================
175
176; update file extension icons
177!macro UpdateIcons
178        Push $R0
179        Push $R1
180        Push $R2
181
182        !define UPDATEICONS_UNIQUE ${__LINE__}
183
184        IfFileExists "$SYSDIR\shell32.dll" UpdateIcons.next1_${UPDATEICONS_UNIQUE} UpdateIcons.error1_${UPDATEICONS_UNIQUE}
185UpdateIcons.next1_${UPDATEICONS_UNIQUE}:
186        GetDllVersion "$SYSDIR\shell32.dll" $R0 $R1
187        IntOp $R2 $R0 / 0x00010000
188        IntCmp $R2 4 UpdateIcons.next2_${UPDATEICONS_UNIQUE} UpdateIcons.error2_${UPDATEICONS_UNIQUE}
189UpdateIcons.next2_${UPDATEICONS_UNIQUE}:
190        System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
191        Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
192
193UpdateIcons.error1_${UPDATEICONS_UNIQUE}:
194        MessageBox MB_OK|MB_ICONSTOP $(JOSM_UPDATEICONS_ERROR1)
195        Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
196UpdateIcons.error2_${UPDATEICONS_UNIQUE}:
197        MessageBox MB_OK|MB_ICONINFORMATION $(JOSM_UPDATEICONS_ERROR2)
198        Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
199UpdateIcons.quit_${UPDATEICONS_UNIQUE}:
200        !undef UPDATEICONS_UNIQUE
201        Pop $R2
202        Pop $R1
203        Pop $R0
204
205!macroend
206
207; associate a file extension to an icon
208Function Associate
209        ; $R0 should contain the prefix to associate to JOSM
210        Push $R1
211
212        ReadRegStr $R1 HKCR $R0 ""
213        StrCmp $R1 "" Associate.doRegister
214        Goto Associate.end
215Associate.doRegister:
216        ;The extension is not associated to any program, we can do the link
217        WriteRegStr HKCR $R0 "" ${OSM_ASSOC}
218Associate.end:
219        pop $R1
220FunctionEnd
221
222; disassociate a file extension from an icon
223Function un.unlink
224        ; $R0 should contain the prefix to unlink
225        Push $R1
226
227        ReadRegStr $R1 HKCR $R0 ""
228        StrCmp $R1 ${OSM_ASSOC} un.unlink.doUnlink
229        Goto un.unlink.end
230un.unlink.doUnlink:
231        ; The extension is associated with JOSM so, we must destroy this!
232        DeleteRegKey HKCR $R0
233un.unlink.end:
234        pop $R1
235FunctionEnd
236
237Function .onInit
238  !insertmacro MUI_LANGDLL_DISPLAY
239FunctionEnd
240
241Function un.onInit
242  !insertmacro MUI_UNGETLANGUAGE
243FunctionEnd
244
245; ============================================================================
246; Installation execution commands
247; ============================================================================
248
249Section "-Required"
250;-------------------------------------------
251
252;
253; Install for every user
254;
255SectionIn 1 2 RO
256SetShellVarContext current
257
258SetOutPath $INSTDIR
259
260; Write the uninstall keys for Windows
261WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "DisplayVersion" "${VERSION}"
262WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "DisplayName" "JOSM ${VERSION}"
263WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "UninstallString" '"$INSTDIR\uninstall.exe"'
264WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "Publisher" "OpenStreetMap JOSM team"
265WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "HelpLink" "mailto:josm-dev@openstreetmap.org."
266WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "URLInfoAbout" "https://josm.openstreetmap.de"
267WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "URLUpdateInfo" "https://josm.openstreetmap.de"
268WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "NoModify" 1
269WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM" "NoRepair" 1
270WriteUninstaller "uninstall.exe"
271
272; Write an entry for ShellExecute
273WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\${DEST}.exe" "" '$INSTDIR\${DEST}.exe'
274WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\${DEST}.exe" "Path" '$INSTDIR'
275
276SectionEnd ; "Required"
277
278
279Section $(JOSM_SEC_JOSM) SecJosm
280;-------------------------------------------
281SectionIn 1
282SetOutPath $INSTDIR
283File "${DEST}.exe"
284File "josm-tested.jar"
285
286; XXX - should be provided/done by josm.jar itself and not here!
287SetShellVarContext current
288SetOutPath "$APPDATA\JOSM"
289
290SectionEnd
291
292SectionGroup $(JOSM_SEC_PLUGINS_GROUP) SecPluginsGroup
293
294Section $(JOSM_SEC_TURNRESTRICTIONS_PLUGIN) SecTurnrestrictionsPlugin
295;-------------------------------------------
296SectionIn 1 2
297SetShellVarContext current
298SetOutPath $APPDATA\JOSM\plugins
299File "../../dist/turnrestrictions.jar"
300StrCpy $plugins "$plugins<entry value='turnrestrictions'/>"
301SectionEnd
302
303Section $(JOSM_SEC_WMS) SecWMS
304;-------------------------------------------
305SectionIn 1 2
306SetShellVarContext current
307SetOutPath $INSTDIR\imageformats
308File "webkit-image\imageformats\qjpeg4.dll"
309SetOutPath $INSTDIR
310File "webkit-image\mingwm10.dll"
311File "webkit-image\QtCore4.dll"
312File "webkit-image\QtGui4.dll"
313File "webkit-image\QtNetwork4.dll"
314File "webkit-image\QtWebKit4.dll"
315File "webkit-image\webkit-image.exe"
316SectionEnd
317
318SectionGroupEnd ; "Plugins"
319
320Section $(JOSM_SEC_STARTMENU) SecStartMenu
321;-------------------------------------------
322SectionIn 1 2
323; To quote "http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dnwue/html/ch11d.asp":
324; "Do not include Readme, Help, or Uninstall entries on the Programs menu."
325CreateShortCut "$SMPROGRAMS\JOSM.lnk" "$INSTDIR\${DEST}.exe" "" "$INSTDIR\${DEST}.exe" 0 "" "" $(JOSM_LINK_TEXT)
326SectionEnd
327
328Section $(JOSM_SEC_DESKTOP_ICON) SecDesktopIcon
329;-------------------------------------------
330; Create desktop icon
331; Desktop icon for a program should not be installed as default!
332CreateShortCut "$DESKTOP\JOSM.lnk" "$INSTDIR\${DEST}.exe" "" "$INSTDIR\${DEST}.exe" 0 "" "" $(JOSM_LINK_TEXT)
333SectionEnd
334
335Section $(JOSM_SEC_QUICKLAUNCH_ICON) SecQuickLaunchIcon
336;-------------------------------------------
337; Create quick launch icon. Does not really exist as of Windows 7/8 but still advanced users use it.
338; Only disable it by default, see #10241
339CreateShortCut "$QUICKLAUNCH\JOSM.lnk" "$INSTDIR\${DEST}.exe" "" "$INSTDIR\${DEST}.exe" 0 "" "" $(JOSM_LINK_TEXT)
340SectionEnd
341
342Section $(JOSM_SEC_FILE_EXTENSIONS) SecFileExtensions
343;-------------------------------------------
344SectionIn 1 2
345; Create File Extensions
346WriteRegStr HKCR ${OSM_ASSOC} "" "OpenStreetMap data"
347WriteRegStr HKCR "${OSM_ASSOC}\Shell\open\command" "" '"$INSTDIR\${DEST}.exe" "%1"'
348WriteRegStr HKCR "${OSM_ASSOC}\DefaultIcon" "" '"$INSTDIR\${DEST}.exe",0'
349push $R0
350        StrCpy $R0 ".osm"
351        Call Associate
352        StrCpy $R0 ".gpx"
353        Call Associate
354; if somethings added here, add it also to the uninstall section
355pop $R0
356!insertmacro UpdateIcons
357SectionEnd
358
359Section "-PluginSetting"
360;-------------------------------------------
361SectionIn 1 2
362;MessageBox MB_OK "PluginSetting!" IDOK 0
363; XXX - should better be handled inside JOSM (recent plugin manager is going in the right direction)
364SetShellVarContext current
365!include LogicLib.nsh
366IfFileExists "$APPDATA\JOSM\preferences" settings_exists
367IfFileExists "$APPDATA\JOSM\preferences.xml" settings_exists
368FileOpen $R0 "$APPDATA\JOSM\preferences.xml" w
369FileWrite $R0 "<?xml version='1.0' encoding='UTF-8'?><preferences xmlns='http://josm.openstreetmap.de/preferences-1.0' version='4660'><list key='plugins'>$plugins</list></preferences>"
370FileClose $R0
371settings_exists:
372SectionEnd
373
374Section "un.$(un.JOSM_SEC_UNINSTALL)" un.SecUinstall
375;-------------------------------------------
376
377;
378; UnInstall for every user
379;
380SectionIn 1 2
381SetShellVarContext current
382
383Delete "$INSTDIR\josm-tested.jar"
384IfErrors 0 NoJOSMErrorMsg
385        MessageBox MB_OK $(un.JOSM_IN_USE_ERROR) IDOK 0 ;skipped if josm.jar removed
386        Abort $(un.JOSM_IN_USE_ERROR)
387NoJOSMErrorMsg:
388Delete "$INSTDIR\${DEST}.exe"
389Delete "$INSTDIR\imageformats\qjpeg4.dll"
390RMDir "$INSTDIR\imageformats"
391Delete "$INSTDIR\mingwm10.dll"
392Delete "$INSTDIR\QtCore4.dll"
393Delete "$INSTDIR\QtGui4.dll"
394Delete "$INSTDIR\QtNetwork4.dll"
395Delete "$INSTDIR\QtWebKit4.dll"
396Delete "$INSTDIR\webkit-image.exe"
397Delete "$INSTDIR\uninstall.exe"
398
399DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\JOSM"
400DeleteRegKey HKEY_LOCAL_MACHINE "Software\${DEST}.exe"
401DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\${DEST}.exe"
402
403; Remove Language preference info
404DeleteRegKey HKCU "Software/JOSM" ;${MUI_LANGDLL_REGISTRY_ROOT} ${MUI_LANGDLL_REGISTRY_KEY}
405
406push $R0
407        StrCpy $R0 ".osm"
408        Call un.unlink
409        StrCpy $R0 ".gpx"
410        Call un.unlink
411pop $R0
412
413DeleteRegKey HKCR ${OSM_ASSOC}
414DeleteRegKey HKCR "${OSM_ASSOC}\Shell\open\command"
415DeleteRegKey HKCR "${OSM_ASSOC}\DefaultIcon"
416!insertmacro UpdateIcons
417
418Delete "$SMPROGRAMS\josm.lnk"
419Delete "$DESKTOP\josm.lnk"
420Delete "$QUICKLAUNCH\josm.lnk"
421
422RMDir "$INSTDIR"
423
424SectionEnd ; "Uninstall"
425
426Section /o "un.$(un.JOSM_SEC_PERSONAL_SETTINGS)" un.SecPersonalSettings
427;-------------------------------------------
428SectionIn 2
429SetShellVarContext current
430Delete "$APPDATA\JOSM\plugins\turnrestrictions\*.*"
431RMDir "$APPDATA\JOSM\plugins\turnrestrictions"
432Delete "$APPDATA\JOSM\plugins\*.*"
433RMDir "$APPDATA\JOSM\plugins"
434
435Delete "$APPDATA\JOSM\motd.html"
436Delete "$APPDATA\JOSM\preferences.xml"
437RMDir "$APPDATA\JOSM"
438SectionEnd
439
440Section "-Un.Finally"
441;-------------------------------------------
442SectionIn 1 2
443; this test must be done after all other things uninstalled (e.g. Global Settings)
444IfFileExists "$INSTDIR" 0 NoFinalErrorMsg
445    MessageBox MB_OK $(un.JOSM_INSTDIR_ERROR) IDOK 0 ; skipped if dir doesn't exist
446NoFinalErrorMsg:
447SectionEnd
448
449; ============================================================================
450; PLEASE MAKE SURE, THAT THE DESCRIPTIVE TEXT FITS INTO THE DESCRIPTION FIELD!
451; ============================================================================
452!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
453  !insertmacro MUI_DESCRIPTION_TEXT ${SecJosm} $(JOSM_SECDESC_JOSM)
454  !insertmacro MUI_DESCRIPTION_TEXT ${SecPluginsGroup} $(JOSM_SECDESC_PLUGINS_GROUP)
455  !insertmacro MUI_DESCRIPTION_TEXT ${SecTurnrestrictionsPlugin} $(JOSM_SECDESC_TURNRESTRICTIONS_PLUGIN)
456  !insertmacro MUI_DESCRIPTION_TEXT ${SecWMS} $(JOSM_SECDESC_WMS)
457  !insertmacro MUI_DESCRIPTION_TEXT ${SecStartMenu} $(JOSM_SECDESC_STARTMENU)
458  !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktopIcon} $(JOSM_SECDESC_DESKTOP_ICON)
459  !insertmacro MUI_DESCRIPTION_TEXT ${SecQuickLaunchIcon} $(JOSM_SECDESC_QUICKLAUNCH_ICON)
460  !insertmacro MUI_DESCRIPTION_TEXT ${SecFileExtensions} $(JOSM_SECDESC_FILE_EXTENSIONS)
461!insertmacro MUI_FUNCTION_DESCRIPTION_END
462
463!insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
464  !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUinstall} $(un.JOSM_SECDESC_UNINSTALL)
465  !insertmacro MUI_DESCRIPTION_TEXT ${un.SecPersonalSettings} $(un.JOSM_SECDESC_PERSONAL_SETTINGS)
466!insertmacro MUI_UNFUNCTION_DESCRIPTION_END
467
468; ============================================================================
469; Callback functions
470; ============================================================================
471
Note: See TracBrowser for help on using the repository browser.