source: josm/trunk/src/org/openstreetmap/josm/gui/mappaint/mapcss/MapCSSParser.jj @ 6686

Last change on this file since 6686 was 6686, checked in by Don-vip, 8 years ago

fix #9575 - support predefined character classes in MapCSS regular expressions (\d, \D, \s, \S, \w, \W)

File size: 16.8 KB
Line 
1// License: GPL. For details, see LICENSE file.
2options {
3  STATIC = false;
4  OUTPUT_DIRECTORY = "parsergen";
5}
6
7PARSER_BEGIN(MapCSSParser)
8package org.openstreetmap.josm.gui.mappaint.mapcss.parsergen;
9
10import java.awt.Color;
11import java.util.ArrayList;
12import java.util.List;
13
14import org.openstreetmap.josm.gui.mappaint.Keyword;
15import org.openstreetmap.josm.gui.mappaint.mapcss.Condition;
16import org.openstreetmap.josm.gui.mappaint.mapcss.Condition.Context;
17import org.openstreetmap.josm.gui.mappaint.mapcss.Expression;
18import org.openstreetmap.josm.gui.mappaint.mapcss.Instruction;
19import org.openstreetmap.josm.gui.mappaint.mapcss.MapCSSRule;
20import org.openstreetmap.josm.gui.mappaint.mapcss.MapCSSStyleSource;
21import org.openstreetmap.josm.gui.mappaint.mapcss.Selector;
22import org.openstreetmap.josm.gui.mappaint.mapcss.ExpressionFactory;
23import org.openstreetmap.josm.gui.mappaint.mapcss.LiteralExpression;
24import org.openstreetmap.josm.gui.mappaint.mapcss.MapCSSException;
25import org.openstreetmap.josm.gui.mappaint.mapcss.Selector.ChildOrParentSelector;
26import org.openstreetmap.josm.gui.mappaint.mapcss.Selector.GeneralSelector;
27import org.openstreetmap.josm.gui.mappaint.mapcss.Selector.LinkSelector;
28import org.openstreetmap.josm.tools.Pair;
29import org.openstreetmap.josm.tools.Utils;
30import org.openstreetmap.josm.Main;
31
32public class MapCSSParser {
33    MapCSSStyleSource sheet;
34}
35PARSER_END(MapCSSParser)
36
37/*************
38 * Token definitions
39 */
40
41<DEFAULT>
42TOKEN:
43{
44    < SET: ("set" | "SET") >
45|   < IDENT: ["a"-"z","A"-"Z","_"] ( ["a"-"z","A"-"Z","_","-","0"-"9"] )* >
46|   < UINT: ["1"-"9"] ( ["0"-"9"] )* >
47|   < UFLOAT: ( ["0"-"9"] )+ ( "." ( ["0"-"9"] )+ )? >
48|   < STRING: "\"" ( [" ","!","#"-"[","]"-"~","\u0080"-"\uFFFF"] | "\\\"" | "\\\\" )*  "\"" >
49|   < #PREDEFINED: "\\" ["d","D","s","S","w","W"] >
50|   < #REGEX_CHAR_WITHOUT_STAR: [" "-")","+"-".","0"-"[","]"-"~","\u0080"-"\uFFFF"] | "\\/" | "\\\\" | "\\[" | "\\]" | "\\+" | "\\." | "\\'" | "\\\"" | <PREDEFINED> >
51|   < REGEX: "/" <REGEX_CHAR_WITHOUT_STAR> ( <REGEX_CHAR_WITHOUT_STAR> | "*" )*  "/" >
52|   < #H: ["0"-"9","a"-"f","A"-"F"] >
53|   < HEXCOLOR: "#" ( <H><H><H><H><H><H> | <H><H><H> ) >
54|   < S: ( " " | "\t" | "\n" | "\r" | "\f" )+ >
55|   < STAR: "*" >
56|   < SLASH: "/" >
57|   < LBRACE: "{" >
58|   < RBRACE: "}" >
59|   < LSQUARE: "[" >
60|   < RSQUARE: "]" >
61|   < LPAR: "(" >
62|   < RPAR: ")" >
63|   < GREATER_EQUAL: ">=" >
64|   < LESS_EQUAL: "<=" >
65|   < GREATER: ">" >
66|   < LESS: "<" >
67|   < EQUAL: "=" >
68|   < EXCLAMATION: "!" >
69|   < TILDE: "~" >
70|   < COLON: ":" >
71|   < DCOLON: "::" >
72|   < SEMICOLON: ";" >
73|   < COMMA: "," >
74|   < PIPE: "|" >
75|   < PIPE_Z: "|z" >
76|   < PLUS: "+" >
77|   < MINUS: "-" >
78|   < AMPERSAND: "&" >
79|   < QUESTION: "?" >
80|   < DOLLAR: "$" >
81|   < CARET: "^" >
82|   < FULLSTOP: "." >
83|   < ELEMENT_OF: "∈" >
84|   < CROSSING: "⧉" >
85|   < COMMENT_START: "/*" > : COMMENT
86|   < UNEXPECTED_CHAR : ~[] > // avoid TokenMgrErrors because they are hard to recover from
87}
88
89<COMMENT>
90TOKEN:
91{
92    < COMMENT_END: "*/" > : DEFAULT
93}
94
95<COMMENT>
96SKIP:
97{
98    < ~[] >
99}
100
101/*************
102 * Parser definitions
103 *
104 *                       rule
105 *  _______________________|______________________________
106 * |                                                      |
107 *        selector                      declaration
108 *  _________|___________________   _________|____________
109 * |                             | |                      |
110 *
111 * way|z11-12[highway=residential] { color: red; width: 3 }
112 *
113 *    |_____||___________________|   |_________|
114 *       |            |                   |
115 *     zoom       condition          instruction
116 *
117 * more general:
118 *
119 * way|z13-[a=b][c=d]::subpart, way|z-3[u=v]:closed::subpart2 { p1 : val; p2 : val; }
120 *
121 * 'val' can be a literal, or an expression like "prop(width, default) + 0.8".
122 *
123 */
124
125int uint() :
126{
127    Token i;
128}
129{
130    i=<UINT> { return Integer.parseInt(i.image); }
131}
132
133int int_() :
134{
135    int i;
136}
137{
138    <MINUS> i=uint() { return -i; } | i=uint() { return i; }
139}
140
141float ufloat() :
142{
143    Token f;
144}
145{
146    ( f=<UFLOAT> | f=<UINT> )
147    { return Float.parseFloat(f.image); }
148}
149
150float float_() :
151{
152    float f;
153}
154{
155    <MINUS> f=ufloat() { return -f; } | f=ufloat() { return f; }
156}
157
158String string() :
159{
160    Token t;
161}
162{
163    t=<STRING>
164    { return t.image.substring(1, t.image.length() - 1).replace("\\\"", "\"").replace("\\\\", "\\"); }
165}
166
167String string_or_ident() :
168{
169    Token t;
170    String s;
171}
172{
173    t=<IDENT> { return t.image; } | s=string() { return s; }
174}
175
176String regex() :
177{
178    Token t;
179}
180{
181    t=<REGEX>
182    { return t.image.substring(1, t.image.length() - 1); }
183}
184
185/**
186 * white-space
187 */
188void s() :
189{
190}
191{
192    ( <S> )?
193}
194
195/**
196 * mix of white-space and comments
197 */
198void w() :
199{
200}
201{
202    ( <S> | <COMMENT_START> <COMMENT_END> )*
203}
204
205/**
206 * comma delimited list of floats (at least 2, all >= 0)
207 */
208List<Float> float_array() :
209{
210    float f;
211    List<Float> fs = new ArrayList<Float>();
212}
213{
214    f=ufloat() { fs.add(f); }
215    (
216        <COMMA> s()
217        f=ufloat() { fs.add(f); }
218    )+
219    {
220        return fs;
221    }
222}
223
224/**
225 * root
226 */
227void sheet(MapCSSStyleSource sheet):
228{
229    MapCSSRule r;
230    Token com = null;
231}
232{
233    { this.sheet = sheet; }
234    w()
235    (
236        try {
237                r=rule() { if (r != null) { sheet.rules.add(r); } } w()
238        } catch (MapCSSException mex) {
239            error_skipto(RBRACE, mex);
240            w();
241        } catch (ParseException ex) {
242            error_skipto(RBRACE, null);
243            w();
244        }
245    )*
246    <EOF>
247}
248
249MapCSSRule rule():
250{
251    List<Selector> selectors = new ArrayList<Selector>();
252    Selector sel;
253    List<Instruction> decl;
254}
255{
256    sel=child_selector() { selectors.add(sel); }
257    (
258        <COMMA> w()
259        sel=child_selector() { selectors.add(sel); }
260    )*
261    decl=declaration()
262    { return new MapCSSRule(selectors, decl); }
263}
264
265Selector child_selector() :
266{
267    Selector.ChildOrParentSelectorType type = null;
268    Condition c;
269    List<Condition> conditions = new ArrayList<Condition>();
270    Selector selLeft;
271    LinkSelector selLink = null;
272    Selector selRight = null;
273}
274{
275    selLeft=selector() w()
276    (
277        (
278            ( <GREATER> { type = Selector.ChildOrParentSelectorType.CHILD; } | <LESS> { type = Selector.ChildOrParentSelectorType.PARENT; } )
279            ( ( c=condition(Context.LINK) | c=class_or_pseudoclass(Context.LINK) ) { conditions.add(c); } )*
280        |
281            <ELEMENT_OF> { type = Selector.ChildOrParentSelectorType.ELEMENT_OF; }
282        |
283            <CROSSING> { type = Selector.ChildOrParentSelectorType.CROSSING; }
284        )
285        { selLink = new LinkSelector(conditions); }
286        w()
287        selRight=selector() w()
288    )?
289    { return selRight != null ? new ChildOrParentSelector(selLeft, selLink, selRight, type) : selLeft; }
290}
291
292Selector selector() :
293{
294    Token base;
295    Condition c;
296    Pair<Integer, Integer> r = null;
297    List<Condition> conditions = new ArrayList<Condition>();
298    String sub = null;
299}
300{
301    ( base=<IDENT> | base=<STAR> )
302    ( r=zoom() )?
303    ( ( c=condition(Context.PRIMITIVE) | c=class_or_pseudoclass(Context.PRIMITIVE) ) { conditions.add(c); } )*
304    ( sub=subpart() )?
305    { return new GeneralSelector(base.image, r, conditions, sub); }
306}
307
308Pair<Integer, Integer> zoom() :
309{
310    Integer min = 0;
311    Integer max = Integer.MAX_VALUE;
312}
313{
314    <PIPE_Z>
315    (
316            <MINUS> max=uint()
317        |
318        LOOKAHEAD(2)
319            min=uint() <MINUS> ( max=uint() )?
320        |
321            min=uint() { max = min; }
322    )
323    { return new Pair<Integer, Integer>(min, max); }
324}
325
326Condition condition(Context context) :
327{
328    Condition c;
329    Expression e;
330}
331{
332    <LSQUARE> s()
333    (
334        LOOKAHEAD( simple_key_condition(context) s() <RSQUARE> )
335            c=simple_key_condition(context) s() <RSQUARE> { return c; }
336        |
337        LOOKAHEAD( simple_key_value_condition(context) s() <RSQUARE> )
338            c=simple_key_value_condition(context) s() <RSQUARE> { return c; }
339        |
340            e=expression() <RSQUARE> { return Condition.createExpressionCondition(e, context); }
341    )
342}
343
344String tag_key() :
345{
346    String s;
347    Token t;
348}
349{
350        s=string() { return s; }
351    |
352        t=<IDENT> { s = t.image; } ( <COLON> t=<IDENT> { s += ':' + t.image; } )* { return s; }
353}
354
355Condition simple_key_condition(Context context) :
356{
357    boolean not = false;
358    Condition.KeyMatchType matchType = null;;
359    String key;
360}
361{
362    ( <EXCLAMATION> { not = true; } )?
363    (
364        { matchType = Condition.KeyMatchType.REGEX; } key = regex()
365    |
366        key = tag_key()
367    )
368    ( LOOKAHEAD(2) <QUESTION> <EXCLAMATION> { matchType = Condition.KeyMatchType.FALSE; } )?
369    (              <QUESTION>               { matchType = Condition.KeyMatchType.TRUE;  } )?
370    { return Condition.createKeyCondition(key, not, matchType, context); }
371}
372
373Condition simple_key_value_condition(Context context) :
374{
375    String key;
376    String val;
377    float f;
378    int i;
379    Condition.Op op;
380    boolean considerValAsKey = false;
381}
382{
383    key=tag_key() s()
384    (
385        LOOKAHEAD(3)
386            (
387                    <EQUAL> <TILDE> { op=Condition.Op.REGEX; }
388                |
389                    <EXCLAMATION> <TILDE> { op=Condition.Op.NREGEX; }
390            )
391            s()
392            ( <STAR> { considerValAsKey=true; } )?
393            val=regex()
394        |
395            (
396                    <EXCLAMATION> <EQUAL> { op=Condition.Op.NEQ; }
397                |
398                    <EQUAL> { op=Condition.Op.EQ; }
399                |
400                    <TILDE> <EQUAL> { op=Condition.Op.ONE_OF; }
401                |
402                    <CARET> <EQUAL> { op=Condition.Op.BEGINS_WITH; }
403                |
404                    <DOLLAR> <EQUAL> { op=Condition.Op.ENDS_WITH; }
405                |
406                    <STAR> <EQUAL> { op=Condition.Op.CONTAINS; }
407            )
408            s()
409            ( <STAR> { considerValAsKey=true; } )?
410            (
411                LOOKAHEAD(2)
412                        i=int_() { val=Integer.toString(i); }
413                    |
414                        f=float_() { val=Float.toString(f); }
415                    |
416                        val=string_or_ident()
417            )
418        |
419            (
420                    <GREATER_EQUAL> { op=Condition.Op.GREATER_OR_EQUAL; }
421                |
422                    <GREATER> { op=Condition.Op.GREATER; }
423                |
424                    <LESS_EQUAL> { op=Condition.Op.LESS_OR_EQUAL; }
425                |
426                    <LESS> { op=Condition.Op.LESS; }
427            )
428            s()
429            f=float_() { val=Float.toString(f); }
430    )
431    { return Condition.createKeyValueCondition(key, val, op, context, considerValAsKey); }
432}
433
434Condition class_or_pseudoclass(Context context) :
435{
436    Token t;
437    boolean not = false;
438    boolean pseudo;
439}
440{
441    ( <EXCLAMATION> { not = true; } )?
442    (
443        <FULLSTOP> { pseudo = false; }
444    |
445        <COLON> { pseudo = true; }
446    )
447    t=<IDENT>
448    { return pseudo
449        ? Condition.createPseudoClassCondition(t.image, not, context)
450        : Condition.createClassCondition(t.image, not, context); }
451}
452
453String subpart() :
454{
455    Token t;
456}
457{
458    <DCOLON>
459    ( t=<IDENT> | t=<STAR> )
460    { return t.image; }
461}
462
463List<Instruction> declaration() :
464{
465    List<Instruction> ins = new ArrayList<Instruction>();
466    Instruction i;
467    Token key;
468    Object val = null;
469}
470{
471    <LBRACE> w()
472    (
473        (
474            <SET> w()
475            (<FULLSTOP>)? // specification allows "set .class" to set "class". we also support "set class"
476            key=<IDENT> w()
477            ( <EQUAL> val=expression() )?
478            { ins.add(new Instruction.AssignmentInstruction(key.image, val == null ? true : val, true)); }
479            ( <RBRACE> { return ins; } | <SEMICOLON> w() )
480        )
481    |
482        key=<IDENT> w() <COLON> w()
483        (
484            LOOKAHEAD( float_array() w() ( <SEMICOLON> | <RBRACE> ) )
485                val=float_array()
486                { ins.add(new Instruction.AssignmentInstruction(key.image, val, false)); }
487                w()
488                ( <RBRACE> { return ins; } | <SEMICOLON> w() )
489            |
490            LOOKAHEAD( expression() ( <SEMICOLON> | <RBRACE> ) )
491                val=expression()
492                { ins.add(new Instruction.AssignmentInstruction(key.image, val, false)); }
493                ( <RBRACE> { return ins; } | <SEMICOLON> w() )
494            |
495                val=readRaw() w() { ins.add(new Instruction.AssignmentInstruction(key.image, val, false)); }
496        )
497    )*
498    <RBRACE>
499    { return ins; }
500}
501
502Expression expression():
503{
504    List<Expression> args = new ArrayList<Expression>();
505    Expression e;
506    String op = null;
507}
508{
509    (
510        <EXCLAMATION> { op = "not"; } w() e=primary() { args.add(e); } w()
511    |
512        <MINUS> { op = "minus"; } w() e=primary() { args.add(e); } w()
513    |
514
515        (
516            e=primary() { args.add(e); } w()
517            (
518                    ( <PLUS> { op = "plus"; } w() e=primary() { args.add(e); } w() )+
519                |
520                    ( <STAR> { op = "times"; } w() e=primary() { args.add(e); } w() )+
521                |
522                    ( <MINUS> { op = "minus"; } w() e=primary() { args.add(e); } w() )+
523                |
524                    ( <SLASH> { op = "divided_by"; } w() e=primary() { args.add(e); } w() )+
525                |
526                    <GREATER_EQUAL> { op = "greater_equal"; } w() e=primary() { args.add(e); } w()
527                |
528                    <LESS_EQUAL> { op = "less_equal"; } w() e=primary() { args.add(e); } w()
529                |
530                    <GREATER> { op = "greater"; } w() e=primary() { args.add(e); } w()
531                |
532                    <EQUAL> ( <EQUAL> )? { op = "equal"; } w() e=primary() { args.add(e); } w()
533                |
534                    <LESS> { op = "less"; } w() e=primary() { args.add(e); } w()
535                |
536                    <AMPERSAND> <AMPERSAND> { op = "and"; } w() e=primary() { args.add(e); } w()
537                |
538                    <PIPE> <PIPE> { op = "or"; } w() e=primary() { args.add(e); } w()
539                |
540                    <QUESTION> { op = "cond"; } w() e=primary() { args.add(e); } w() <COLON> w() e=primary() { args.add(e); } w()
541            )?
542        )
543    )
544    {
545        if (op == null)
546            return args.get(0);
547        return ExpressionFactory.createFunctionExpression(op, args);
548    }
549}
550
551Expression primary() :
552{
553    Expression nested;
554    Expression fn;
555    Object lit;
556}
557{
558    LOOKAHEAD(3) // both function and identifier start with an identifier (+ optional whitespace)
559        fn=function() { return fn; }
560    |
561        lit=literal() { return new LiteralExpression(lit); }
562    |
563        <LPAR> w() nested=expression() <RPAR> { return nested; }
564}
565
566Expression function() :
567{
568    Token tmp;
569    Expression arg;
570    String name;
571    List<Expression> args = new ArrayList<Expression>();
572}
573{
574    tmp=<IDENT> { name = tmp.image; } w()
575    <LPAR> w()
576    (
577        arg=expression() { args.add(arg); }
578        ( <COMMA> w() arg=expression() { args.add(arg); } )*
579    )?
580    <RPAR>
581    { return ExpressionFactory.createFunctionExpression(name, args); }
582}
583
584Object literal() :
585{
586    String val;
587    Token t;
588    float f;
589}
590{
591        t=<IDENT> { return new Keyword(t.image); }
592    |
593        val=string() { return val; }
594    |
595        <PLUS> f=ufloat() { return new Instruction.RelativeFloat(f); }
596    |
597        f=ufloat() { return f; }
598    |
599        t=<HEXCOLOR> { return Utils.hexToColor(t.image); }
600}
601
602JAVACODE
603void error_skipto(int kind, MapCSSException me) {
604    if (token.kind == EOF)
605        throw new ParseException("Reached end of file while parsing");
606       
607    Exception e = null;       
608    ParseException pe = generateParseException();
609
610    if (me != null) {
611        me.setLine(pe.currentToken.next.beginLine);
612        me.setColumn(pe.currentToken.next.beginColumn);
613        e = me;
614    } else {
615        e = new ParseException(pe.getMessage()); // prevent memory leak
616    }
617   
618    Main.error("Skipping to the next rule, because of an error:");
619    Main.error(e);
620    if (sheet != null) {
621        sheet.logError(e);
622    }
623    Token t;
624    do {
625        t = getNextToken();
626    } while (t.kind != kind && t.kind != EOF);
627    if (t.kind == EOF)
628        throw new ParseException("Reached end of file while parsing");
629}
630
631JAVACODE
632/**
633 * read everything to the next semicolon
634 */
635String readRaw() {
636    Token t;
637    StringBuilder s = new StringBuilder();
638    while (true) {
639        t = getNextToken();
640        if ((t.kind == S || t.kind == STRING || t.kind == UNEXPECTED_CHAR) &&
641                t.image.contains("\n")) {
642            ParseException e = new ParseException(String.format("Warning: end of line while reading an unquoted string at line %s column %s.", t.beginLine, t.beginColumn));
643            Main.error(e);
644            if (sheet != null) {
645                sheet.logError(e);
646            }
647        }
648        if (t.kind == SEMICOLON || t.kind == EOF)
649            break;
650        s.append(t.image);
651    }
652    if (t.kind == EOF)
653        throw new ParseException("Reached end of file while parsing");
654    return s.toString();
655}
656
Note: See TracBrowser for help on using the repository browser.