source: josm/trunk/scripts/SyncEditorLayerIndex.groovy @ 13517

Last change on this file since 13517 was 13517, checked in by stoecker, 6 years ago

don't issue error for http/https switches in JOSM
  • Property svn:eol-style set to native
File size: 37.3 KB
Line 
1// License: GPL. For details, see LICENSE file.
2/**
3 * Compare and analyse the differences of the editor layer index and the JOSM imagery list.
4 * The goal is to keep both lists in sync.
5 *
6 * The editor layer index project (https://github.com/osmlab/editor-layer-index)
7 * provides also a version in the JOSM format, but the GEOJSON is the original source
8 * format, so we read that.
9 *
10 * How to run:
11 * -----------
12 *
13 * Main JOSM binary needs to be in classpath, e.g.
14 *
15 * $ groovy -cp ../dist/josm-custom.jar SyncEditorLayerIndex.groovy
16 *
17 * Add option "-h" to show the available command line flags.
18 */
19import java.text.DecimalFormat
20import javax.json.Json
21import javax.json.JsonArray
22import javax.json.JsonObject
23import javax.json.JsonReader
24
25import org.openstreetmap.josm.data.imagery.ImageryInfo
26import org.openstreetmap.josm.data.imagery.Shape
27import org.openstreetmap.josm.io.imagery.ImageryReader
28
29class SyncEditorLayerIndex {
30
31    List<ImageryInfo> josmEntries;
32    JsonArray eliEntries;
33
34    def eliUrls = new HashMap<String, JsonObject>()
35    def josmUrls = new HashMap<String, ImageryInfo>()
36    def josmMirrors = new HashMap<String, ImageryInfo>()
37
38    static String eliInputFile = 'imagery_eli.geojson'
39    static String josmInputFile = 'imagery_josm.imagery.xml'
40    static String ignoreInputFile = 'imagery_josm.ignores.txt'
41    static FileOutputStream outputFile = null
42    static OutputStreamWriter outputStream = null
43    def skip = [:]
44
45    static def options
46
47    /**
48     * Main method.
49     */
50    static main(def args) {
51        Locale.setDefault(Locale.ROOT);
52        parse_command_line_arguments(args)
53        def script = new SyncEditorLayerIndex()
54        script.loadSkip()
55        script.start()
56        script.loadJosmEntries()
57        if(options.josmxml) {
58            def file = new FileOutputStream(options.josmxml)
59            def stream = new OutputStreamWriter(file, "UTF-8")
60            script.printentries(script.josmEntries, stream)
61            stream.close();
62            file.close();
63        }
64        script.loadELIEntries()
65        if(options.elixml) {
66            def file = new FileOutputStream(options.elixml)
67            def stream = new OutputStreamWriter(file, "UTF-8")
68            script.printentries(script.eliEntries, stream)
69            stream.close();
70            file.close();
71        }
72        script.checkInOneButNotTheOther()
73        script.checkCommonEntries()
74        script.end()
75        if(outputStream != null) {
76            outputStream.close();
77        }
78        if(outputFile != null) {
79            outputFile.close();
80        }
81    }
82
83    /**
84     * Parse command line arguments.
85     */
86    static void parse_command_line_arguments(args) {
87        def cli = new CliBuilder(width: 160)
88        cli.o(longOpt:'output', args:1, argName: "output", "Output file, - prints to stdout (default: -)")
89        cli.e(longOpt:'eli_input', args:1, argName:"eli_input", "Input file for the editor layer index (geojson). Default is $eliInputFile (current directory).")
90        cli.j(longOpt:'josm_input', args:1, argName:"josm_input", "Input file for the JOSM imagery list (xml). Default is $josmInputFile (current directory).")
91        cli.i(longOpt:'ignore_input', args:1, argName:"ignore_input", "Input file for the ignore list. Default is $ignoreInputFile (current directory).")
92        cli.s(longOpt:'shorten', "shorten the output, so it is easier to read in a console window")
93        cli.n(longOpt:'noskip', argName:"noskip", "don't skip known entries")
94        cli.x(longOpt:'xhtmlbody', argName:"xhtmlbody", "create XHTML body for display in a web page")
95        cli.X(longOpt:'xhtml', argName:"xhtml", "create XHTML for display in a web page")
96        cli.p(longOpt:'elixml', args:1, argName:"elixml", "ELI entries for use in JOSM as XML file (incomplete)")
97        cli.q(longOpt:'josmxml', args:1, argName:"josmxml", "JOSM entries reoutput as XML file (incomplete)")
98        cli.m(longOpt:'noeli', argName:"noeli", "don't show output for ELI problems")
99        cli.h(longOpt:'help', "show this help")
100        options = cli.parse(args)
101
102        if (options.h) {
103            cli.usage()
104            System.exit(0)
105        }
106        if (options.eli_input) {
107            eliInputFile = options.eli_input
108        }
109        if (options.josm_input) {
110            josmInputFile = options.josm_input
111        }
112        if (options.ignore_input) {
113            ignoreInputFile = options.ignore_input
114        }
115        if (options.output && options.output != "-") {
116            outputFile = new FileOutputStream(options.output)
117            outputStream = new OutputStreamWriter(outputFile, "UTF-8")
118        }
119    }
120
121    void loadSkip() {
122        def fr = new InputStreamReader(new FileInputStream(ignoreInputFile), "UTF-8")
123        def line
124
125        while((line = fr.readLine()) != null) {
126            def res = (line =~ /^\|\| *(ELI|Ignore) *\|\| *\{\{\{(.+)\}\}\} *\|\|/)
127            if(res.count)
128            {
129                if(res[0][1].equals("Ignore")) {
130                    skip[res[0][2]] = "green"
131                } else {
132                    skip[res[0][2]] = "darkgoldenrod"
133                }
134            }
135        }
136    }
137
138    void myprintlnfinal(String s) {
139        if(outputStream != null) {
140            outputStream.write(s+System.getProperty("line.separator"))
141        } else {
142            println s
143        }
144    }
145
146    void myprintln(String s) {
147        if(skip.containsKey(s)) {
148            String color = skip.get(s)
149            skip.remove(s)
150            if(options.xhtmlbody || options.xhtml) {
151                s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
152            }
153            if (!options.noskip) {
154                return
155            }
156        } else if(options.xhtmlbody || options.xhtml) {
157            String color = s.startsWith("***") ? "black" : ((s.startsWith("+ ") || s.startsWith("+++ ELI")) ? "blue" :  (s.startsWith("#") ? "indigo" : "red"))
158            s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
159        }
160        if ((s.startsWith("+ ") || s.startsWith("+++ ELI") || s.startsWith("#")) && options.noeli) {
161            return
162        }
163        myprintlnfinal(s)
164    }
165
166    void start() {
167        if (options.xhtml) {
168            myprintlnfinal "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">\n"
169            myprintlnfinal "<html><head><meta http-equiv=\"Content-Type\" content=\"text/html; charset=UTF-8\"/><title>JOSM - ELI differences</title></head><body>\n"
170        }
171    }
172
173    void end() {
174        for (def s: skip.keySet()) {
175            myprintln "+++ Obsolete skip entry: " + s
176        }
177        if (options.xhtml) {
178            myprintlnfinal "</body></html>\n"
179        }
180    }
181
182    void loadELIEntries() {
183        FileReader fr = new FileReader(eliInputFile)
184        JsonReader jr = Json.createReader(fr)
185        eliEntries = jr.readObject().get("features")
186        jr.close()
187
188        for (def e : eliEntries) {
189            def url = getUrlStripped(e)
190            if (url.contains("{z}")) {
191                myprintln "+++ ELI-URL uses {z} instead of {zoom}: "+url
192                url = url.replace("{z}","{zoom}")
193            }
194            if (eliUrls.containsKey(url)) {
195                myprintln "+++ ELI-URL is not unique: "+url
196            } else {
197                eliUrls.put(url, e)
198            }
199        }
200        myprintln "*** Loaded ${eliEntries.size()} entries (ELI). ***"
201    }
202    String cdata(def s, boolean escape = false) {
203        if(escape) {
204            return s.replaceAll("&", "&amp;").replaceAll("<", "&lt;").replaceAll(">", "&gt;")
205        } else if(s =~ /[<>&]/)
206            return "<![CDATA[$s]]>"
207       return s
208    }
209
210    String maininfo(def entry, String offset) {
211        String t = getType(entry)
212        String res = offset + "<type>$t</type>\n"
213        res += offset + "<url>${cdata(getUrl(entry))}</url>\n"
214        if(getMinZoom(entry) != null)
215            res += offset + "<min-zoom>${getMinZoom(entry)}</min-zoom>\n"
216        if(getMaxZoom(entry) != null)
217            res += offset + "<max-zoom>${getMaxZoom(entry)}</max-zoom>\n"
218        if (t == "wms") {
219            def p = getProjections(entry)
220            if (p) {
221                res += offset + "<projections>\n"
222                for (def c : p)
223                    res += offset + "    <code>$c</code>\n"
224                res += offset + "</projections>\n"
225            }
226        }
227        return res
228    }
229
230    void printentries(def entries, def stream) {
231        DecimalFormat df = new DecimalFormat("#.#######")
232        df.setRoundingMode(java.math.RoundingMode.CEILING)
233        stream.write "<?xml version=\"1.0\" encoding=\"UTF-8\" standalone=\"yes\"?>\n"
234        stream.write "<imagery xmlns=\"http://josm.openstreetmap.de/maps-1.0\">\n"
235        for (def e : entries) {
236            def best = "eli-best".equals(getQuality(e))
237            stream.write "    <entry"+(best ? " eli-best=\"true\"" : "" )+">\n"
238            stream.write "        <name>${cdata(getName(e), true)}</name>\n"
239            stream.write "        <id>${getId(e)}</id>\n"
240            def t
241            if((t = getDate(e)))
242                stream.write "        <date>$t</date>\n"
243            if((t = getCountryCode(e)))
244                stream.write "        <country-code>$t</country-code>\n"
245            if((getDefault(e)))
246                stream.write "        <default>true</default>\n"
247            stream.write maininfo(e, "        ")
248            if((t = getAttributionText(e)))
249                stream.write "        <attribution-text mandatory=\"true\">${cdata(t, true)}</attribution-text>\n"
250            if((t = getAttributionUrl(e)))
251                stream.write "        <attribution-url>${cdata(t)}</attribution-url>\n"
252            if((t = getLogoImage(e)))
253                stream.write "        <logo-image>${cdata(t, true)}</logo-image>\n"
254            if((t = getLogoUrl(e)))
255                stream.write "        <logo-url>${cdata(t)}</logo-url>\n"
256            if((t = getTermsOfUseText(e)))
257                stream.write "        <terms-of-use-text>${cdata(t, true)}</terms-of-use-text>\n"
258            if((t = getTermsOfUseUrl(e)))
259                stream.write "        <terms-of-use-url>${cdata(t)}</terms-of-use-url>\n"
260            if((t = getPermissionReferenceUrl(e)))
261                stream.write "        <permission-ref>${cdata(t)}</permission-ref>\n"
262            if((getValidGeoreference(e)))
263                stream.write "        <valid-georeference>true</valid-georeference>\n"
264            if((t = getIcon(e)))
265                stream.write "        <icon>${cdata(t)}</icon>\n"
266            for (def d : getDescriptions(e)) {
267                    stream.write "        <description lang=\"${d.getKey()}\">${d.getValue()}</description>\n"
268            }
269            for (def m : getMirrors(e)) {
270                    stream.write "        <mirror>\n"+maininfo(m, "            ")+"        </mirror>\n"
271            }
272            def minlat = 1000
273            def minlon = 1000
274            def maxlat = -1000
275            def maxlon = -1000
276            def shapes = ""
277            def sep = "\n            "
278            for(def s: getShapes(e)) {
279                shapes += "            <shape>"
280                def i = 0
281                for(def p: s.getPoints()) {
282                    def lat = p.getLat()
283                    def lon = p.getLon()
284                    if(lat > maxlat) maxlat = lat
285                    if(lon > maxlon) maxlon = lon
286                    if(lat < minlat) minlat = lat
287                    if(lon < minlon) minlon = lon
288                    if(!(i++%3)) {
289                        shapes += sep + "    "
290                    }
291                    shapes += "<point lat='${df.format(lat)}' lon='${df.format(lon)}'/>"
292                }
293                shapes += sep + "</shape>\n"
294            }
295            if(shapes) {
296                stream.write "        <bounds min-lat='${df.format(minlat)}' min-lon='${df.format(minlon)}' max-lat='${df.format(maxlat)}' max-lon='${df.format(maxlon)}'>\n"
297                stream.write shapes + "        </bounds>\n"
298            }
299            stream.write "    </entry>\n"
300        }
301        stream.write "</imagery>\n"
302        stream.close()
303    }
304
305    void loadJosmEntries() {
306        def reader = new ImageryReader(josmInputFile)
307        josmEntries = reader.parse()
308
309        for (def e : josmEntries) {
310            def url = getUrlStripped(e)
311            if (url.contains("{z}")) {
312                myprintln "+++ JOSM-URL uses {z} instead of {zoom}: "+url
313                url = url.replace("{z}","{zoom}")
314            }
315            if (josmUrls.containsKey(url)) {
316                myprintln "+++ JOSM-URL is not unique: "+url
317            } else {
318                josmUrls.put(url, e)
319            }
320            for (def m : e.getMirrors()) {
321                url = getUrlStripped(m)
322                m.origName = m.getOriginalName().replaceAll(" mirror server( \\d+)?","")
323                if (josmUrls.containsKey(url)) {
324                    myprintln "+++ JOSM-Mirror-URL is not unique: "+url
325                } else {
326                    josmUrls.put(url, m)
327                    josmMirrors.put(url, m)
328                }
329            }
330        }
331        myprintln "*** Loaded ${josmEntries.size()} entries (JOSM). ***"
332    }
333
334    List inOneButNotTheOther(Map m1, Map m2, String code, String https) {
335        def l = []
336        for (def url : m1.keySet()) {
337            if (!m2.containsKey(url)) {
338                String urlhttps = url.replace("http:","https:")
339                if(!https || !m2.containsKey(urlhttps))
340                {
341                    def name = getName(m1.get(url))
342                    l += code+"  "+getDescription(m1.get(url))
343                }
344                else
345                {
346                    l += https+" Missing https: "+getDescription(m1.get(url))
347                }
348            }
349        }
350        l.sort()
351    }
352
353    void checkInOneButNotTheOther() {
354        def l1 = inOneButNotTheOther(eliUrls, josmUrls, "-", "+")
355        myprintln "*** URLs found in ELI but not in JOSM (${l1.size()}): ***"
356        if (!l1.isEmpty()) {
357            for (def l : l1) {
358                myprintln l
359            }
360        }
361
362        def l2 = inOneButNotTheOther(josmUrls, eliUrls, "+", "")
363        myprintln "*** URLs found in JOSM but not in ELI (${l2.size()}): ***"
364        if (!l2.isEmpty()) {
365            for (def l : l2) {
366                myprintln l
367            }
368        }
369    }
370
371    void checkCommonEntries() {
372        myprintln "*** Same URL, but different name: ***"
373        for (def url : eliUrls.keySet()) {
374            def e = eliUrls.get(url)
375            if (!josmUrls.containsKey(url)) continue
376            def j = josmUrls.get(url)
377            def ename = getName(e).replace("'","\u2019")
378            def jname = getName(j).replace("'","\u2019")
379            if (!ename.equals(jname)) {
380                myprintln "* Name differs ('${getName(e)}' != '${getName(j)}'): ${getUrl(j)}"
381            }
382        }
383
384        myprintln "*** Same URL, but different Id: ***"
385        for (def url : eliUrls.keySet()) {
386            def e = eliUrls.get(url)
387            if (!josmUrls.containsKey(url)) continue
388            def j = josmUrls.get(url)
389            def ename = getId(e)
390            def jname = getId(j)
391            if (!ename.equals(jname)) {
392                myprintln "# Id differs ('${getId(e)}' != '${getId(j)}'): ${getUrl(j)}"
393            }
394        }
395
396        myprintln "*** Same URL, but different type: ***"
397        for (def url : eliUrls.keySet()) {
398            def e = eliUrls.get(url)
399            if (!josmUrls.containsKey(url)) continue
400            def j = josmUrls.get(url)
401            if (!getType(e).equals(getType(j))) {
402                myprintln "* Type differs (${getType(e)} != ${getType(j)}): ${getName(j)} - ${getUrl(j)}"
403            }
404        }
405
406        myprintln "*** Same URL, but different zoom bounds: ***"
407        for (def url : eliUrls.keySet()) {
408            def e = eliUrls.get(url)
409            if (!josmUrls.containsKey(url)) continue
410            def j = josmUrls.get(url)
411
412            Integer eMinZoom = getMinZoom(e)
413            Integer jMinZoom = getMinZoom(j)
414            if (eMinZoom != jMinZoom  && !(eMinZoom == 0 && jMinZoom == null)) {
415                myprintln "* Minzoom differs (${eMinZoom} != ${jMinZoom}): ${getDescription(j)}"
416            }
417            Integer eMaxZoom = getMaxZoom(e)
418            Integer jMaxZoom = getMaxZoom(j)
419            if (eMaxZoom != jMaxZoom) {
420                myprintln "* Maxzoom differs (${eMaxZoom} != ${jMaxZoom}): ${getDescription(j)}"
421            }
422        }
423
424        myprintln "*** Same URL, but different country code: ***"
425        for (def url : eliUrls.keySet()) {
426            def e = eliUrls.get(url)
427            if (!josmUrls.containsKey(url)) continue
428            def j = josmUrls.get(url)
429            if (!getCountryCode(e).equals(getCountryCode(j))) {
430                myprintln "* Country code differs (${getCountryCode(e)} != ${getCountryCode(j)}): ${getDescription(j)}"
431            }
432        }
433        myprintln "*** Same URL, but different quality: ***"
434        for (def url : eliUrls.keySet()) {
435            def e = eliUrls.get(url)
436            if (!josmUrls.containsKey(url)) {
437              def q = getQuality(e)
438              if("eli-best".equals(q)) {
439                myprintln "- Quality best entry not in JOSM for ${getDescription(e)}"
440              }
441              continue
442            }
443            def j = josmUrls.get(url)
444            if (!getQuality(e).equals(getQuality(j))) {
445                myprintln "* Quality differs (${getQuality(e)} != ${getQuality(j)}): ${getDescription(j)}"
446            }
447        }
448        myprintln "*** Same URL, but different dates: ***"
449        for (def url : eliUrls.keySet()) {
450            def ed = getDate(eliUrls.get(url))
451            if (!josmUrls.containsKey(url)) continue
452            def j = josmUrls.get(url)
453            def jd = getDate(j)
454            // The forms 2015;- or -;2015 or 2015;2015 are handled equal to 2015
455            String ef = ed.replaceAll("\\A-;","").replaceAll(";-\\z","").replaceAll("\\A([0-9-]+);\\1\\z","\$1")
456            // ELI has a strange and inconsistent used end_date definition, so we try again with subtraction by one
457            String ed2 = ed
458            def reg = (ed =~ /^(.*;)(\d\d\d\d)(-(\d\d)(-(\d\d))?)?$/)
459            if(reg != null && reg.count == 1) {
460                Calendar cal = Calendar.getInstance()
461                cal.set(reg[0][2] as Integer, reg[0][4] == null ? 0 : (reg[0][4] as Integer)-1, reg[0][6] == null ? 1 : reg[0][6] as Integer)
462                cal.add(Calendar.DAY_OF_MONTH, -1)
463                ed2 = reg[0][1] + cal.get(Calendar.YEAR)
464                if (reg[0][4] != null)
465                    ed2 += "-" + String.format("%02d", cal.get(Calendar.MONTH)+1)
466                if (reg[0][6] != null)
467                    ed2 += "-" + String.format("%02d", cal.get(Calendar.DAY_OF_MONTH))
468            }
469            String ef2 = ed2.replaceAll("\\A-;","").replaceAll(";-\\z","").replaceAll("\\A([0-9-]+);\\1\\z","\$1")
470            if (!ed.equals(jd) && !ef.equals(jd) && !ed2.equals(jd) && !ef2.equals(jd)) {
471                String t = "'${ed}'"
472                if (!ed.equals(ef)) {
473                    t += " or '${ef}'"
474                }
475                if (jd.isEmpty()) {
476                    myprintln "- Missing JOSM date (${t}): ${getDescription(j)}"
477                } else if (!ed.isEmpty()) {
478                    myprintln "* Date differs ('${t}' != '${jd}'): ${getDescription(j)}"
479                } else if (!options.nomissingeli) {
480                    myprintln "+ Missing ELI date ('${jd}'): ${getDescription(j)}"
481                }
482            }
483        }
484        myprintln "*** Same URL, but different information: ***"
485        for (def url : eliUrls.keySet()) {
486            if (!josmUrls.containsKey(url)) continue
487            def e = eliUrls.get(url)
488            def j = josmUrls.get(url)
489
490            def et = getDescriptions(e)
491            def jt = getDescriptions(j)
492            et = (et.size() > 0) ? et["en"] : ""
493            jt = (jt.size() > 0) ? jt["en"] : ""
494            if (!et.equals(jt)) {
495                if (!jt) {
496                    myprintln "- Missing JOSM description (${et}): ${getDescription(j)}"
497                } else if (et) {
498                    myprintln "* Description differs ('${et}' != '${jt}'): ${getDescription(j)}"
499                } else if (!options.nomissingeli) {
500                    myprintln "+ Missing ELI description ('${jt}'): ${getDescription(j)}"
501                }
502            }
503
504            et = getPermissionReferenceUrl(e)
505            jt = getPermissionReferenceUrl(j)
506            if (!jt) jt = getTermsOfUseUrl(j)
507            if (!et.equals(jt)) {
508                if (!jt) {
509                    myprintln "- Missing JOSM license URL (${et}): ${getDescription(j)}"
510                } else if (et) {
511                    myprintln "* License URL differs ('${et}' != '${jt}'): ${getDescription(j)}"
512                } else if (!options.nomissingeli) {
513                    myprintln "+ Missing ELI license URL ('${jt}'): ${getDescription(j)}"
514                }
515            }
516
517            et = getAttributionUrl(e)
518            jt = getAttributionUrl(j)
519            if (!et.equals(jt)) {
520                if (!jt) {
521                    myprintln "- Missing JOSM attribution URL (${et}): ${getDescription(j)}"
522                } else if (et) {
523                    myprintln "* Attribution URL differs ('${et}' != '${jt}'): ${getDescription(j)}"
524                } else if (!options.nomissingeli) {
525                    myprintln "+ Missing ELI attribution URL ('${jt}'): ${getDescription(j)}"
526                }
527            }
528
529            et = getAttributionText(e)
530            jt = getAttributionText(j)
531            if (!et.equals(jt)) {
532                if (!jt) {
533                    myprintln "- Missing JOSM attribution text (${et}): ${getDescription(j)}"
534                } else if (et) {
535                    myprintln "* Attribution text differs ('${et}' != '${jt}'): ${getDescription(j)}"
536                } else if (!options.nomissingeli) {
537                    myprintln "+ Missing ELI attribution text ('${jt}'): ${getDescription(j)}"
538                }
539            }
540
541            et = getProjections(e)
542            jt = getProjections(j)
543            if (et) { et = new LinkedList(et); Collections.sort(et); et = String.join(" ", et) }
544            if (jt) { jt = new LinkedList(jt); Collections.sort(jt); jt = String.join(" ", jt) }
545            if (!et.equals(jt)) {
546                if (!jt) {
547                    myprintln "- Missing JOSM projections (${et}): ${getDescription(j)}"
548                } else if (et) {
549                    myprintln "* Projections differ ('${et}' != '${jt}'): ${getDescription(j)}"
550                } else if (!options.nomissingeli && !getType(e).equals("tms")) {
551                    myprintln "+ Missing ELI projections ('${jt}'): ${getDescription(j)}"
552                }
553            }
554
555            et = getDefault(e)
556            jt = getDefault(j)
557            if (!et.equals(jt)) {
558                if (!jt) {
559                    myprintln "- Missing JOSM default: ${getDescription(j)}"
560                } else if (!options.nomissingeli) {
561                    myprintln "+ Missing ELI default: ${getDescription(j)}"
562                }
563            }
564        }
565        myprintln "*** Mismatching shapes: ***"
566        for (def url : josmUrls.keySet()) {
567            def j = josmUrls.get(url)
568            def num = 1
569            for (def shape : getShapes(j)) {
570                def p = shape.getPoints()
571                if(!p[0].equals(p[p.size()-1])) {
572                    myprintln "+++ JOSM shape $num unclosed: ${getDescription(j)}"
573                }
574                for (def nump = 1; nump < p.size(); ++nump) {
575                    if (p[nump-1] == p[nump]) {
576                        myprintln "+++ JOSM shape $num double point at ${nump-1}: ${getDescription(j)}"
577                    }
578                }
579                ++num
580            }
581        }
582        for (def url : eliUrls.keySet()) {
583            def e = eliUrls.get(url)
584            def num = 1
585            def s = getShapes(e)
586            for (def shape : s) {
587                def p = shape.getPoints()
588                if(!p[0].equals(p[p.size()-1]) && !options.nomissingeli) {
589                    myprintln "+++ ELI shape $num unclosed: ${getDescription(e)}"
590                }
591                for (def nump = 1; nump < p.size(); ++nump) {
592                    if (p[nump-1] == p[nump]) {
593                        myprintln "+++ ELI shape $num double point at ${nump-1}: ${getDescription(e)}"
594                    }
595                }
596                ++num
597            }
598            if (!josmUrls.containsKey(url)) {
599                continue
600            }
601            def j = josmUrls.get(url)
602            def js = getShapes(j)
603            if(!s.size() && js.size()) {
604                if(!options.nomissingeli) {
605                    myprintln "+ No ELI shape: ${getDescription(j)}"
606                }
607            } else if(!js.size() && s.size()) {
608                // don't report boundary like 5 point shapes as difference
609                if (s.size() != 1 || s[0].getPoints().size() != 5) {
610                    myprintln "- No JOSM shape: ${getDescription(j)}"
611                }
612            } else if(s.size() != js.size()) {
613                myprintln "* Different number of shapes (${s.size()} != ${js.size()}): ${getDescription(j)}"
614            } else {
615                for(def nums = 0; nums < s.size(); ++nums) {
616                    def ep = s[nums].getPoints()
617                    def jp = js[nums].getPoints()
618                    if(ep.size() != jp.size()) {
619                        myprintln "* Different number of points for shape ${nums+1} (${ep.size()} ! = ${jp.size()})): ${getDescription(j)}"
620                    } else {
621                        for(def nump = 0; nump < ep.size(); ++nump) {
622                            def ept = ep[nump]
623                            def jpt = jp[nump]
624                            if(Math.abs(ept.getLat()-jpt.getLat()) > 0.000001 || Math.abs(ept.getLon()-jpt.getLon()) > 0.000001) {
625                                myprintln "* Different coordinate for point ${nump+1} of shape ${nums+1}: ${getDescription(j)}"
626                                nump = ep.size()
627                                num = s.size()
628                            }
629                        }
630                    }
631                }
632            }
633        }
634        myprintln "*** Mismatching icons: ***"
635        for (def url : eliUrls.keySet()) {
636            def e = eliUrls.get(url)
637            if (!josmUrls.containsKey(url)) {
638                continue
639            }
640            def j = josmUrls.get(url)
641            def ij = getIcon(j)
642            def ie = getIcon(e)
643            if(ij != null && ie == null) {
644                if(!options.nomissingeli) {
645                    myprintln "+ No ELI icon: ${getDescription(j)}"
646                }
647            } else if(ij == null && ie != null) {
648                myprintln "- No JOSM icon: ${getDescription(j)}"
649            } else if(!ij.equals(ie)) {
650                myprintln "* Different icons: ${getDescription(j)}"
651            }
652        }
653        myprintln "*** Miscellaneous checks: ***"
654        def josmIds = new HashMap<String, ImageryInfo>()
655        for (def url : josmUrls.keySet()) {
656            def j = josmUrls.get(url)
657            def id = getId(j)
658            if("wms".equals(getType(j)) && !getProjections(j)) {
659                myprintln "* WMS without projections: ${getDescription(j)}"
660            }
661            if(josmMirrors.containsKey(url)) {
662                continue
663            }
664            if(id == null) {
665                myprintln "* No JOSM-ID: ${getDescription(j)}"
666            } else if(josmIds.containsKey(id)) {
667                myprintln "* JOSM-ID ${id} not unique: ${getDescription(j)}"
668            } else {
669                josmIds.put(id, j)
670            }
671            def d = getDate(j)
672            if(!d.isEmpty()) {
673                def reg = (d =~ /^(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?)(;(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?))?$/)
674                if(reg == null || reg.count != 1) {
675                    myprintln "* JOSM-Date '${d}' is strange: ${getDescription(j)}"
676                } else {
677                    try {
678                        def first = verifyDate(reg[0][2],reg[0][4],reg[0][6])
679                        def second = verifyDate(reg[0][9],reg[0][11],reg[0][13])
680                        if(second.compareTo(first) < 0) {
681                            myprintln "* JOSM-Date '${d}' is strange (second earlier than first): ${getDescription(j)}"
682                        }
683                    }
684                    catch (Exception e) {
685                        myprintln "* JOSM-Date '${d}' is strange (${e.getMessage()}): ${getDescription(j)}"
686                    }
687                }
688            }
689            if(getAttributionUrl(j) && !getAttributionText(j)) {
690                myprintln "* Attribution link without text: ${getDescription(j)}"
691            }
692            if(getLogoUrl(j) && !getLogoImage(j)) {
693                myprintln "* Logo link without image: ${getDescription(j)}"
694            }
695            if(getTermsOfUseText(j) && !getTermsOfUseUrl(j)) {
696                myprintln "* Terms of Use text without link: ${getDescription(j)}"
697            }
698            def js = getShapes(j)
699            if(js.size()) {
700                def minlat = 1000
701                def minlon = 1000
702                def maxlat = -1000
703                def maxlon = -1000
704                for(def s: js) {
705                    for(def p: s.getPoints()) {
706                        def lat = p.getLat()
707                        def lon = p.getLon()
708                        if(lat > maxlat) maxlat = lat
709                        if(lon > maxlon) maxlon = lon
710                        if(lat < minlat) minlat = lat
711                        if(lon < minlon) minlon = lon
712                    }
713                }
714                def b = j.getBounds()
715                if(b.getMinLat() != minlat || b.getMinLon() != minlon || b.getMaxLat() != maxlat || b.getMaxLon() != maxlon) {
716                    myprintln "* Bounds do not match shape (is ${b.getMinLat()},${b.getMinLon()},${b.getMaxLat()},${b.getMaxLon()}, calculated <bounds min-lat='${minlat}' min-lon='${minlon}' max-lat='${maxlat}' max-lon='${maxlon}'>): ${getDescription(j)}"
717                }
718            }
719        }
720    }
721
722    /**
723     * Utility functions that allow uniform access for both ImageryInfo and JsonObject.
724     */
725    static String getUrl(Object e) {
726        if (e instanceof ImageryInfo) return e.url
727        return e.get("properties").getString("url")
728    }
729    static String getUrlStripped(Object e) {
730        return getUrl(e).replaceAll("\\?(apikey|access_token)=.*","")
731    }
732    static String getDate(Object e) {
733        if (e instanceof ImageryInfo) return e.date ? e.date : ""
734        def p = e.get("properties")
735        def start = p.containsKey("start_date") ? p.getString("start_date") : ""
736        def end = p.containsKey("end_date") ? p.getString("end_date") : ""
737        if(!start.isEmpty() && !end.isEmpty())
738            return start+";"+end
739        else if(!start.isEmpty())
740            return start+";-"
741        else if(!end.isEmpty())
742            return "-;"+end
743        return ""
744    }
745    static Date verifyDate(String year, String month, String day) {
746        def date
747        if(year == null) {
748            date = "3000-01-01"
749        } else {
750            date = year + "-" + (month == null ? "01" : month) + "-" + (day == null ? "01" : day)
751        }
752        def df = new java.text.SimpleDateFormat("yyyy-MM-dd")
753        df.setLenient(false)
754        return df.parse(date)
755    }
756    static String getId(Object e) {
757        if (e instanceof ImageryInfo) return e.getId()
758        return e.get("properties").getString("id")
759    }
760    static String getName(Object e) {
761        if (e instanceof ImageryInfo) return e.getOriginalName()
762        return e.get("properties").getString("name")
763    }
764    static List<Object> getMirrors(Object e) {
765        if (e instanceof ImageryInfo) return e.getMirrors()
766        return []
767    }
768    static List<Object> getProjections(Object e) {
769        def r
770        if (e instanceof ImageryInfo) {
771            r = e.getServerProjections()
772        } else {
773            def s = e.get("properties").get("available_projections")
774            if (s) {
775                r = []
776                for (def p : s)
777                    r += p.getString()
778            }
779        }
780        return r ? r : []
781    }
782    static List<Shape> getShapes(Object e) {
783        if (e instanceof ImageryInfo) {
784            def bounds = e.getBounds()
785            if(bounds != null) {
786                return bounds.getShapes()
787            }
788            return []
789        }
790        if(!e.isNull("geometry")) {
791            def ex = e.get("geometry")
792            if(ex != null && !ex.isNull("coordinates")) {
793                def poly = ex.get("coordinates")
794                List<Shape> l = []
795                for(def shapes: poly) {
796                    def s = new Shape()
797                    for(def point: shapes) {
798                        def lon = point[0].toString()
799                        def lat = point[1].toString()
800                        s.addPoint(lat, lon)
801                    }
802                    l.add(s)
803                }
804                return l
805            }
806        }
807        return []
808    }
809    static String getType(Object e) {
810        if (e instanceof ImageryInfo) return e.getImageryType().getTypeString()
811        return e.get("properties").getString("type")
812    }
813    static Integer getMinZoom(Object e) {
814        if (e instanceof ImageryInfo) {
815            if("wms".equals(getType(e)) && e.getName() =~ / mirror/)
816                return null;
817            int mz = e.getMinZoom()
818            return mz == 0 ? null : mz
819        } else {
820            def num = e.get("properties").getJsonNumber("min_zoom")
821            if (num == null) return null
822            return num.intValue()
823        }
824    }
825    static Integer getMaxZoom(Object e) {
826        if (e instanceof ImageryInfo) {
827            if("wms".equals(getType(e)) && e.getName() =~ / mirror/)
828                return null;
829            int mz = e.getMaxZoom()
830            return mz == 0 ? null : mz
831        } else {
832            def num = e.get("properties").getJsonNumber("max_zoom")
833            if (num == null) return null
834            return num.intValue()
835        }
836    }
837    static String getCountryCode(Object e) {
838        if (e instanceof ImageryInfo) return "".equals(e.getCountryCode()) ? null : e.getCountryCode()
839        return e.get("properties").getString("country_code", null)
840    }
841    static String getQuality(Object e) {
842        if (e instanceof ImageryInfo) return e.isBestMarked() ? "eli-best" : null
843        return (e.get("properties").containsKey("best")
844            && e.get("properties").getBoolean("best")) ? "eli-best" : null
845    }
846    static String getIcon(Object e) {
847        if (e instanceof ImageryInfo) return e.getIcon()
848        return e.get("properties").getString("icon", null)
849    }
850    static String getAttributionText(Object e) {
851        if (e instanceof ImageryInfo) return e.getAttributionText(0, null, null)
852        try {return e.get("properties").get("attribution").getString("text", null)} catch (NullPointerException ex) {return null}
853    }
854    static String getAttributionUrl(Object e) {
855        if (e instanceof ImageryInfo) return e.getAttributionLinkURL()
856        try {return e.get("properties").get("attribution").getString("url", null)} catch (NullPointerException ex) {return null}
857    }
858    static String getTermsOfUseText(Object e) {
859        if (e instanceof ImageryInfo) return e.getTermsOfUseText()
860        return null
861    }
862    static String getTermsOfUseUrl(Object e) {
863        if (e instanceof ImageryInfo) return e.getTermsOfUseURL()
864        return null
865    }
866    static String getLogoImage(Object e) {
867        if (e instanceof ImageryInfo) return e.getAttributionImageRaw()
868        return null
869    }
870    static String getLogoUrl(Object e) {
871        if (e instanceof ImageryInfo) return e.getAttributionImageURL()
872        return null
873    }
874    static String getPermissionReferenceUrl(Object e) {
875        if (e instanceof ImageryInfo) return e.getPermissionReferenceURL()
876        return e.get("properties").getString("license_url", null)
877    }
878    static Map<String,String> getDescriptions(Object e) {
879        Map<String,String> res = new HashMap<String, String>()
880        if (e instanceof ImageryInfo) {
881          String a = e.getDescription()
882          if (a) res.put("en", a)
883        } else {
884          String a = e.get("properties").getString("description", null)
885          if (a) res.put("en", a)
886        }
887        return res
888    }
889    static Boolean getValidGeoreference(Object e) {
890        if (e instanceof ImageryInfo) return e.isGeoreferenceValid()
891        return false
892    }
893    static Boolean getDefault(Object e) {
894        if (e instanceof ImageryInfo) return e.isDefaultEntry()
895        return e.get("properties").getBoolean("default", false)
896    }
897    String getDescription(Object o) {
898        def url = getUrl(o)
899        def cc = getCountryCode(o)
900        if (cc == null) {
901            def j = josmUrls.get(url)
902            if (j != null) cc = getCountryCode(j)
903            if (cc == null) {
904                def e = eliUrls.get(url)
905                if (e != null) cc = getCountryCode(e)
906            }
907        }
908        if (cc == null) {
909            cc = ''
910        } else {
911            cc = "[$cc] "
912        }
913        def d = cc + getName(o) + " - " + getUrl(o)
914        if (options.shorten) {
915            def MAXLEN = 140
916            if (d.length() > MAXLEN) d = d.substring(0, MAXLEN-1) + "..."
917        }
918        return d
919    }
920}
Note: See TracBrowser for help on using the repository browser.