source: josm/trunk/scripts/SyncEditorLayerIndex.groovy @ 11665

Last change on this file since 11665 was 11665, checked in by Klumbumbus, 2 years ago

see #12706 - enable ELI date comparison script

  • Property svn:eol-style set to native
File size: 23.0 KB
Line 
1// License: GPL. For details, see LICENSE file.
2/**
3 * Compare and analyse the differences of the editor imagery index and the JOSM imagery list.
4 * The goal is to keep both lists in sync.
5 *
6 * The editor imagery index project (https://github.com/osmlab/editor-imagery-index)
7 * provides also a version in the JOSM format, but the JSON is the original source
8 * format, so we read that.
9 *
10 * How to run:
11 * -----------
12 *
13 * Main JOSM binary needs to be in classpath, e.g.
14 *
15 * $ groovy -cp ../dist/josm-custom.jar SyncEditorImageryIndex.groovy
16 *
17 * Add option "-h" to show the available command line flags.
18 */
19import javax.json.Json
20import javax.json.JsonArray
21import javax.json.JsonObject
22import javax.json.JsonReader
23import javax.json.JsonValue
24
25import org.openstreetmap.josm.data.imagery.ImageryInfo
26import org.openstreetmap.josm.data.imagery.Shape
27import org.openstreetmap.josm.io.imagery.ImageryReader
28
29class SyncEditorImageryIndex {
30
31    List<ImageryInfo> josmEntries;
32    JsonArray eliEntries;
33
34    def eliUrls = new HashMap<String, JsonObject>()
35    def josmUrls = new HashMap<String, ImageryInfo>()
36    def josmMirrors = new HashMap<String, ImageryInfo>()
37
38    static String eliInputFile = 'imagery.geojson'
39    static String josmInputFile = 'maps.xml'
40    static String ignoreInputFile = 'maps_ignores.txt'
41    static FileWriter outputFile = null
42    static BufferedWriter outputStream = null
43    def skip = [:]
44
45    static def options
46
47    /**
48     * Main method.
49     */
50    static main(def args) {
51        parse_command_line_arguments(args)
52        def script = new SyncEditorImageryIndex()
53        script.loadSkip()
54        script.start()
55        script.loadJosmEntries()
56        script.loadELIEntries()
57        script.checkInOneButNotTheOther()
58        script.checkCommonEntries()
59        script.end()
60        if(outputStream != null) {
61            outputStream.close();
62        }
63        if(outputFile != null) {
64            outputFile.close();
65        }
66    }
67
68    /**
69     * Parse command line arguments.
70     */
71    static void parse_command_line_arguments(args) {
72        def cli = new CliBuilder(width: 160)
73        cli.o(longOpt:'output', args:1, argName: "output", "Output file, - prints to stdout (default: -)")
74        cli.e(longOpt:'eli_input', args:1, argName:"eli_input", "Input file for the editor imagery index (json). Default is $eliInputFile (current directory).")
75        cli.j(longOpt:'josm_input', args:1, argName:"josm_input", "Input file for the JOSM imagery list (xml). Default is $josmInputFile (current directory).")
76        cli.i(longOpt:'ignore_input', args:1, argName:"ignore_input", "Input file for the ignore list. Default is $ignoreInputFile (current directory).")
77        cli.s(longOpt:'shorten', "shorten the output, so it is easier to read in a console window")
78        cli.n(longOpt:'noskip', argName:"noskip", "don't skip known entries")
79        cli.x(longOpt:'xhtmlbody', argName:"xhtmlbody", "create XHTML body for display in a web page")
80        cli.X(longOpt:'xhtml', argName:"xhtml", "create XHTML for display in a web page")
81        cli.m(longOpt:'nomissingeli', argName:"nomissingeli", "don't show missing editor imagery index entries")
82        cli.h(longOpt:'help', "show this help")
83        options = cli.parse(args)
84
85        if (options.h) {
86            cli.usage()
87            System.exit(0)
88        }
89        if (options.eli_input) {
90            eliInputFile = options.eli_input
91        }
92        if (options.josm_input) {
93            josmInputFile = options.josm_input
94        }
95        if (options.ignore_input) {
96            ignoreInputFile = options.ignore_input
97        }
98        if (options.output && options.output != "-") {
99            outputFile = new FileWriter(options.output)
100            outputStream = new BufferedWriter(outputFile)
101        }
102    }
103
104    void loadSkip() {
105        FileReader fr = new FileReader(ignoreInputFile)
106        def line
107
108        while((line = fr.readLine()) != null) {
109            def res = (line =~ /^\|\| *(ELI|Ignore) *\|\| *\{\{\{(.+)\}\}\} *\|\|/)
110            if(res.count)
111            {
112                if(res[0][1].equals("Ignore")) {
113                    skip[res[0][2]] = "green"
114                } else {
115                    skip[res[0][2]] = "darkgoldenrod"
116                }
117            }
118        }
119    }
120
121    void myprintlnfinal(String s) {
122        if(outputStream != null) {
123            outputStream.write(s);
124            outputStream.newLine();
125        } else {
126            println s;
127        }
128    }
129
130    void myprintln(String s) {
131        if(skip.containsKey(s)) {
132            String color = skip.get(s)
133            skip.remove(s)
134            if(options.xhtmlbody || options.xhtml) {
135                s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
136            }
137            if (!options.noskip) {
138                return;
139            }
140        } else if(options.xhtmlbody || options.xhtml) {
141            String color = s.startsWith("***") ? "black" : ((s.startsWith("+ ") || s.startsWith("+++ ELI")) ? "blue" : "red")
142            s = "<pre style=\"margin:3px;color:"+color+"\">"+s.replaceAll("&","&amp;").replaceAll("<","&lt;").replaceAll(">","&gt;")+"</pre>"
143        }
144        myprintlnfinal(s)
145    }
146
147    void start() {
148        if (options.xhtml) {
149            myprintlnfinal "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">\n"
150            myprintlnfinal "<html><head><meta http-equiv=\"Content-Type\" content=\"text/html; charset=UTF-8\"/><title>JOSM - ELI differences</title></head><body>\n"
151        }
152    }
153
154    void end() {
155        for (def s: skip.keySet()) {
156            myprintln "+++ Obsolete skip entry: " + s
157        }
158        if (options.xhtml) {
159            myprintlnfinal "</body></html>\n"
160        }
161    }
162
163    void loadELIEntries() {
164        FileReader fr = new FileReader(eliInputFile)
165        JsonReader jr = Json.createReader(fr)
166        eliEntries = jr.readObject().get("features")
167        jr.close()
168
169        for (def e : eliEntries) {
170            def url = getUrl(e)
171            if (url.contains("{z}")) {
172                myprintln "+++ ELI-URL uses {z} instead of {zoom}: "+url
173                url = url.replace("{z}","{zoom}")
174            }
175            if (eliUrls.containsKey(url)) {
176                myprintln "+++ ELI-URL is not unique: "+url
177            } else {
178                eliUrls.put(url, e)
179            }
180        }
181        myprintln "*** Loaded ${eliEntries.size()} entries (ELI). ***"
182    }
183
184    void loadJosmEntries() {
185        def reader = new ImageryReader(josmInputFile)
186        josmEntries = reader.parse()
187
188        for (def e : josmEntries) {
189            def url = getUrl(e)
190            if (url.contains("{z}")) {
191                myprintln "+++ JOSM-URL uses {z} instead of {zoom}: "+url
192                url = url.replace("{z}","{zoom}")
193            }
194            if (josmUrls.containsKey(url)) {
195                myprintln "+++ JOSM-URL is not unique: "+url
196            } else {
197                josmUrls.put(url, e)
198            }
199            for (def m : e.getMirrors()) {
200                url = getUrl(m)
201                m.origName = m.getOriginalName().replaceAll(" mirror server( \\d+)?","")
202                if (josmUrls.containsKey(url)) {
203                    myprintln "+++ JOSM-Mirror-URL is not unique: "+url
204                } else {
205                    josmUrls.put(url, m)
206                    josmMirrors.put(url, m)
207                }
208            }
209        }
210        myprintln "*** Loaded ${josmEntries.size()} entries (JOSM). ***"
211    }
212
213    List inOneButNotTheOther(Map m1, Map m2) {
214        def l = []
215        for (def url : m1.keySet()) {
216            if (!m2.containsKey(url)) {
217                def name = getName(m1.get(url))
218                l += "  "+getDescription(m1.get(url))
219            }
220        }
221        l.sort()
222    }
223
224    void checkInOneButNotTheOther() {
225        def l1 = inOneButNotTheOther(eliUrls, josmUrls)
226        myprintln "*** URLs found in ELI but not in JOSM (${l1.size()}): ***"
227        if (!l1.isEmpty()) {
228            for (def l : l1) {
229                myprintln "-" + l
230            }
231        }
232
233        if (options.nomissingeli)
234            return
235        def l2 = inOneButNotTheOther(josmUrls, eliUrls)
236        myprintln "*** URLs found in JOSM but not in ELI (${l2.size()}): ***"
237        if (!l2.isEmpty()) {
238            for (def l : l2) {
239                myprintln "+" + l
240            }
241        }
242    }
243
244    void checkCommonEntries() {
245        myprintln "*** Same URL, but different name: ***"
246        for (def url : eliUrls.keySet()) {
247            def e = eliUrls.get(url)
248            if (!josmUrls.containsKey(url)) continue
249            def j = josmUrls.get(url)
250            if (!getName(e).equals(getName(j))) {
251                myprintln "* Name differs ('${getName(e)}' != '${getName(j)}'): $url"
252            }
253        }
254
255        myprintln "*** Same URL, but different type: ***"
256        for (def url : eliUrls.keySet()) {
257            def e = eliUrls.get(url)
258            if (!josmUrls.containsKey(url)) continue
259            def j = josmUrls.get(url)
260            if (!getType(e).equals(getType(j))) {
261                myprintln "* Type differs (${getType(e)} != ${getType(j)}): ${getName(j)} - $url"
262            }
263        }
264
265        myprintln "*** Same URL, but different zoom bounds: ***"
266        for (def url : eliUrls.keySet()) {
267            def e = eliUrls.get(url)
268            if (!josmUrls.containsKey(url)) continue
269            def j = josmUrls.get(url)
270
271            Integer eMinZoom = getMinZoom(e)
272            Integer jMinZoom = getMinZoom(j)
273            if (eMinZoom != jMinZoom  && !(eMinZoom == 0 && jMinZoom == null)) {
274                myprintln "* Minzoom differs (${eMinZoom} != ${jMinZoom}): ${getDescription(j)}"
275            }
276            Integer eMaxZoom = getMaxZoom(e)
277            Integer jMaxZoom = getMaxZoom(j)
278            if (eMaxZoom != jMaxZoom) {
279                myprintln "* Maxzoom differs (${eMaxZoom} != ${jMaxZoom}): ${getDescription(j)}"
280            }
281        }
282
283        myprintln "*** Same URL, but different country code: ***"
284        for (def url : eliUrls.keySet()) {
285            def e = eliUrls.get(url)
286            if (!josmUrls.containsKey(url)) continue
287            def j = josmUrls.get(url)
288            if (!getCountryCode(e).equals(getCountryCode(j))) {
289                myprintln "* Country code differs (${getCountryCode(e)} != ${getCountryCode(j)}): ${getDescription(j)}"
290            }
291        }
292        myprintln "*** Same URL, but different quality: ***"
293        for (def url : eliUrls.keySet()) {
294            def e = eliUrls.get(url)
295            if (!josmUrls.containsKey(url)) {
296              def q = getQuality(e)
297              if("eli-best".equals(q)) {
298                myprintln "- Quality best entry not in JOSM for ${getDescription(e)}"
299              }
300              continue
301            }
302            def j = josmUrls.get(url)
303            if (!getQuality(e).equals(getQuality(j))) {
304                myprintln "* Quality differs (${getQuality(e)} != ${getQuality(j)}): ${getDescription(j)}"
305            }
306        }
307        myprintln "*** Same URL, but different dates: ***"
308        for (def url : eliUrls.keySet()) {
309            def ed = getDate(eliUrls.get(url))
310            if (!josmUrls.containsKey(url)) continue
311            def j = josmUrls.get(url)
312            def jd = getDate(j)
313            // The forms 2015;- or -;2015 or 2015;2015 are handled equal to 2015
314            String ef = ed.replaceAll("\\A-;","").replaceAll(";-\\z","").replaceAll("\\A([0-9-]+);\\1\\z","\$1");
315            // ELI has a strange and inconsistent used end_date definition, so we try again with subtraction by one
316            String ed2 = ed;
317            def reg = (ed =~ /^(.*;)(\d\d\d\d)(-(\d\d)(-(\d\d))?)?$/)
318            if(reg != null && reg.count == 1) {
319                Calendar cal = Calendar.getInstance();
320                cal.set(reg[0][2] as Integer, reg[0][4] == null ? 0 : (reg[0][4] as Integer)-1, reg[0][6] == null ? 1 : reg[0][6] as Integer)
321                cal.add(Calendar.DAY_OF_MONTH, -1)
322                ed2 = cal.get(Calendar.YEAR)
323                if (reg[0][4] != null)
324                    ed2 += "-" + String.format("%02d", cal.get(Calendar.MONTH)+1)
325                if (reg[0][6] != null)
326                    ed2 += "-" + String.format("%02d", cal.get(Calendar.DAY_OF_MONTH))
327            }
328            String ef2 = ed2.replaceAll("\\A-;","").replaceAll(";-\\z","").replaceAll("\\A([0-9-]+);\\1\\z","\$1");
329            if (!ed.equals(jd) && !ef.equals(jd) && !ed2.equals(jd) && !ef2.equals(jd)) {
330                String t = "'${ed}'";
331                if (!ed.equals(ef)) {
332                    t += " or '${ef}'";
333                }
334                myprintln "* Date differs (${t} != '${jd}'): ${getDescription(j)}"
335            }
336        }
337        myprintln "*** Mismatching shapes: ***"
338        for (def url : josmUrls.keySet()) {
339            def j = josmUrls.get(url)
340            def num = 1
341            for (def shape : getShapes(j)) {
342                def p = shape.getPoints()
343                if(!p[0].equals(p[p.size()-1])) {
344                    myprintln "+++ JOSM shape $num unclosed: ${getDescription(j)}"
345                }
346                ++num
347            }
348        }
349        for (def url : eliUrls.keySet()) {
350            def e = eliUrls.get(url)
351            def num = 1
352            def s = getShapes(e)
353            for (def shape : s) {
354                def p = shape.getPoints()
355                if(!p[0].equals(p[p.size()-1]) && !options.nomissingeli) {
356                    myprintln "+++ ELI shape $num unclosed: ${getDescription(e)}"
357                }
358                ++num
359            }
360            if (!josmUrls.containsKey(url)) {
361                continue
362            }
363            def j = josmUrls.get(url)
364            def js = getShapes(j)
365            if(!s.size() && js.size()) {
366                if(!options.nomissingeli) {
367                    myprintln "+ No ELI shape: ${getDescription(j)}"
368                }
369            } else if(!js.size() && s.size()) {
370                // don't report boundary like 5 point shapes as difference
371                if (s.size() != 1 || s[0].getPoints().size() != 5) {
372                    myprintln "- No JOSM shape: ${getDescription(j)}"
373                }
374            } else if(s.size() != js.size()) {
375                myprintln "* Different number of shapes (${s.size()} != ${js.size()}): ${getDescription(j)}"
376            } else {
377                for(def nums = 0; nums < s.size(); ++nums) {
378                    def ep = s[nums].getPoints()
379                    def jp = js[nums].getPoints()
380                    if(ep.size() != jp.size()) {
381                        myprintln "* Different number of points for shape ${nums+1} (${ep.size()} ! = ${jp.size()})): ${getDescription(j)}"
382                    } else {
383                        for(def nump = 0; nump < ep.size(); ++nump) {
384                            def ept = ep[nump]
385                            def jpt = jp[nump]
386                            if(Math.abs(ept.getLat()-jpt.getLat()) > 0.000001 || Math.abs(ept.getLon()-jpt.getLon()) > 0.000001) {
387                                myprintln "* Different coordinate for point ${nump+1} of shape ${nums+1}: ${getDescription(j)}"
388                                nump = ep.size()
389                                num = s.size()
390                            }
391                        }
392                    }
393                }
394            }
395        }
396        myprintln "*** Mismatching icons: ***"
397        for (def url : eliUrls.keySet()) {
398            def e = eliUrls.get(url)
399            if (!josmUrls.containsKey(url)) {
400                continue
401            }
402            def j = josmUrls.get(url)
403            def ij = getIcon(j)
404            def ie = getIcon(e)
405            if(ij != null && ie == null) {
406                if(!options.nomissingeli) {
407                    myprintln "+ No ELI icon: ${getDescription(j)}"
408                }
409            } else if(ij == null && ie != null) {
410                myprintln "- No JOSM icon: ${getDescription(j)}"
411            } else if(!ij.equals(ie)) {
412                myprintln "* Different icons: ${getDescription(j)}"
413            }
414        }
415        myprintln "*** Miscellaneous checks: ***"
416        def josmIds = new HashMap<String, ImageryInfo>()
417        for (def url : josmUrls.keySet()) {
418            def j = josmUrls.get(url)
419            def id = getId(j)
420            if(josmMirrors.containsKey(url)) {
421                continue;
422            }
423            if(id == null) {
424                myprintln "* No JOSM-ID: ${getDescription(j)}"
425            } else if(josmIds.containsKey(id)) {
426                myprintln "* JOSM-ID ${id} not unique: ${getDescription(j)}"
427            } else {
428                josmIds.put(id, j);
429            }
430            def d = getDate(j)
431            if(!d.isEmpty()) {
432                def reg = (d =~ /^(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?)(;(-|(\d\d\d\d)(-(\d\d)(-(\d\d))?)?))?$/)
433                if(reg == null || reg.count != 1) {
434                    myprintln "* JOSM-Date '${d}' is strange: ${getDescription(j)}"
435                } else {
436                    try {
437                        def first = verifyDate(reg[0][2],reg[0][4],reg[0][6]);
438                        def second = verifyDate(reg[0][9],reg[0][11],reg[0][13]);
439                        if(second.compareTo(first) < 0) {
440                            myprintln "* JOSM-Date '${d}' is strange (second earlier than first): ${getDescription(j)}"
441                        }
442                    }
443                    catch (Exception e) {
444                        myprintln "* JOSM-Date '${d}' is strange (${e.getMessage()}): ${getDescription(j)}"
445                    }
446                }
447            }
448            def js = getShapes(j)
449            if(js.size()) {
450                def minlat = 1000;
451                def minlon = 1000;
452                def maxlat = -1000;
453                def maxlon = -1000;
454                for(def s: js) {
455                    for(def p: s.getPoints()) {
456                        def lat = p.getLat();
457                        def lon = p.getLon();
458                        if(lat > maxlat) maxlat = lat;
459                        if(lon > maxlon) maxlon = lon;
460                        if(lat < minlat) minlat = lat;
461                        if(lon < minlon) minlon = lon;
462                    }
463                }
464                def b = j.getBounds();
465                if(b.getMinLat() != minlat || b.getMinLon() != minlon || b.getMaxLat() != maxlat || b.getMaxLon() != maxlon) {
466                    myprintln "* Bounds do not match shape (is ${b.getMinLat()},${b.getMinLon()},${b.getMaxLat()},${b.getMaxLon()}, calculated <bounds min-lat='${minlat}' min-lon='${minlon}' max-lat='${maxlat}' max-lon='${maxlon}'>): ${getDescription(j)}"
467                }
468            }
469        }
470    }
471
472    /**
473     * Utility functions that allow uniform access for both ImageryInfo and JsonObject.
474     */
475    static String getUrl(Object e) {
476        if (e instanceof ImageryInfo) return e.url
477        return e.get("properties").getString("url")
478    }
479    static String getDate(Object e) {
480        if (e instanceof ImageryInfo) return e.date ? e.date : ""
481        def p = e.get("properties")
482        def start = p.containsKey("start_date") ? p.getString("start_date") : ""
483        def end = p.containsKey("end_date") ? p.getString("end_date") : ""
484        if(!start.isEmpty() && !end.isEmpty())
485            return start+";"+end
486        else if(!start.isEmpty())
487            return start+";-"
488        else if(!end.isEmpty())
489            return "-;"+end
490        return "";
491    }
492    static Date verifyDate(String year, String month, String day) {
493        def date
494        if(year == null)
495            date = "3000-01-01"
496        else
497            date = year + "-" + (month == null ? "01" : month) + "-" + (day == null ? "01" : day)
498        def df = new java.text.SimpleDateFormat("yyyy-MM-dd")
499        df.setLenient(false)
500        return df.parse(date)
501    }
502    static String getId(Object e) {
503        if (e instanceof ImageryInfo) return e.getId()
504        return e.get("properties").getString("id")
505    }
506    static String getName(Object e) {
507        if (e instanceof ImageryInfo) return e.getOriginalName()
508        return e.get("properties").getString("name")
509    }
510    static List<Shape> getShapes(Object e) {
511        if (e instanceof ImageryInfo) {
512            def bounds = e.getBounds();
513            if(bounds != null) {
514                return bounds.getShapes();
515            }
516            return []
517        }
518        if(!e.isNull("geometry")) {
519            def ex = e.get("geometry")
520            if(ex != null && !ex.isNull("coordinates")) {
521                def poly = ex.get("coordinates")
522                List<Shape> l = []
523                for(def shapes: poly) {
524                    def s = new Shape()
525                    for(def point: shapes) {
526                        def lon = point[0].toString()
527                        def lat = point[1].toString()
528                        s.addPoint(lat, lon)
529                    }
530                    l.add(s)
531                }
532                return l
533            }
534        }
535        return []
536    }
537    static String getType(Object e) {
538        if (e instanceof ImageryInfo) return e.getImageryType().getTypeString()
539        return e.get("properties").getString("type")
540    }
541    static Integer getMinZoom(Object e) {
542        if (e instanceof ImageryInfo) {
543            int mz = e.getMinZoom()
544            return mz == 0 ? null : mz
545        } else {
546            def num = e.get("properties").getJsonNumber("min_zoom")
547            if (num == null) return null
548            return num.intValue()
549        }
550    }
551    static Integer getMaxZoom(Object e) {
552        if (e instanceof ImageryInfo) {
553            int mz = e.getMaxZoom()
554            return mz == 0 ? null : mz
555        } else {
556            def num = e.get("properties").getJsonNumber("max_zoom")
557            if (num == null) return null
558            return num.intValue()
559        }
560    }
561    static String getCountryCode(Object e) {
562        if (e instanceof ImageryInfo) return "".equals(e.getCountryCode()) ? null : e.getCountryCode()
563        return e.get("properties").getString("country_code", null)
564    }
565    static String getQuality(Object e) {
566        if (e instanceof ImageryInfo) return e.isBestMarked() ? "eli-best" : null
567        return (e.get("properties").containsKey("best")
568            && e.get("properties").getBoolean("best")) ? "eli-best" : null
569    }
570    static String getIcon(Object e) {
571        if (e instanceof ImageryInfo) return e.getIcon()
572        return e.get("properties").getString("icon", null)
573    }
574    String getDescription(Object o) {
575        def url = getUrl(o)
576        def cc = getCountryCode(o)
577        if (cc == null) {
578            def j = josmUrls.get(url)
579            if (j != null) cc = getCountryCode(j)
580            if (cc == null) {
581                def e = eliUrls.get(url)
582                if (e != null) cc = getCountryCode(e)
583            }
584        }
585        if (cc == null) {
586            cc = ''
587        } else {
588            cc = "[$cc] "
589        }
590        def d = cc + getName(o) + " - " + getUrl(o)
591        if (options.shorten) {
592            def MAXLEN = 140
593            if (d.length() > MAXLEN) d = d.substring(0, MAXLEN-1) + "..."
594        }
595        return d
596    }
597}
Note: See TracBrowser for help on using the repository browser.